#include "PROTHEUS.CH"
#include "RWMAKE.CH"
#include "APWEBEX.CH"
#include "TOPCONN.CH"
#include "TBICONN.CH"
#DEFINE SMSDEBUG
/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ AddOrc      ¦ Autor ¦ Lucilene Mendes     ¦ Data ¦28.08.17 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Inclusão de Orçamento de Venda.							  ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/

User Function AddOrc()
Local cHtml
Local cItem 	:= ""
Local cCondNot	:= ""
Local nPosFrete	:= 0
Local nPerCom	:= 0
Local nValCom	:= 0
Local nOpc		:= 0
Local nLin		:= 0
Local f			:= 0
Local lMoeda	:= .F.
Local lNumber	:= .F.
Local aTpFrete	:= {}
Private cFilVen		:= ""
Private cCodLogin 	:= ""
Private cVendLogin	:= ""
Private cVendedor	:= ""
Private cSite	  	:= "u_PortalLogin.apw"
Private cPagina	  	:= "Orçamento de Venda"
Private cTitle	  	:= "Portal SMS"
Private cMenus	  	:= ""
Private cAnexos	  	:= ""
Private cDirOrc		:= "\anexosPortal\orcamentos\"
Private cDirPortal 	:= ""
Private cEndServ 	:= "" // Endereço do servidor da pagina de Portal
Private cOrcCabec	:= ""
Private cOrcItens	:= ""
Private cItensHid	:= ""
Private cBotoes		:= ""
Private cBtnItens	:= ""
Private cOptProd	:= ""
Private cOptCond	:= ""
Private cOptCli		:= ""
Private cTblDesc	:= ""

Private cFilOrc		:= ""
Private cCodOrc		:= ""
Private cCliente	:= ""
Private cContato	:= ""
Private cContDDD	:= ""
Private cContTel	:= ""
Private cTpCliente	:= ""
Private cGrpTrib	:= ""
Private cCondPag	:= ""
Private cLocalEnt	:= ""
Private cObra		:= ""
Private cStatusObra := ""
Private cIntermed	:= ""
Private cOport		:= ""
Private cRevOpt		:= ""
Private cRegional	:= ""
Private cTpFrete	:= ""
Private cValFre		:= ""
Private cPrazoEmb	:= ""
Private cEstudo		:= ""
Private cNumEst		:= ""
Private cPrevFecha	:= ""
Private cMargemCont	:= ""
Private cTransp		:= ""
//Private cEntrega	:= ""
//Private cValidade	:= ""

Private nTVlrUnit	:= 0
Private nTQtdItem   := 0
Private nTTotal		:= 0
Private nTComiss	:= 0
Private nTImpostos	:= 0
Private nTAcresc	:= 0
Private nTFrete		:= 0
Private nItens		:= 0
Private lNewOrc		:= .T.
Private lEdit		:= .F.
Private lCopy		:= .F.
Private aItens	  	:= {}
Private aAnexos   	:= {}

	Web Extended Init cHtml Start U_inSite()

	cVendLogin := u_GetUsrPR()
	cCodLogin  := U_SetParPR(cVendLogin)

	If Empty(HttpSession->CodVend)
		cHtml:= '<META HTTP-EQUIV="Refresh" CONTENT="0 ; URL='+cSite+'">'
		Return cHtml
	Else
		If !Empty(HttpSession->Superv) .and. HttpSession->Superv <> HttpSession->CodVend
			HttpSession->CodVend:= HttpSession->Superv
		Endif
	Endif

	// Pega do parâmetro com o Titulo do Portal
	cTitle	:= SuperGetMV("PS_TITLE", .T., "Portal SMS")

	// Define a funcao a ser chama no link
	cSite	:= "u_SMSPortal.apw?PR="+cCodLogin

	// Monta o cabeçalho para a pagina
	cHeader := U_PSHeader(cTitle, cSite)

	//Função que atualiza os menus
	cMenus := U_GetMenus(AllTrim(Upper(Procname())), cVendLogin)

//Atualiza as variáveis
	cEndServ := GetMv('MV_WFBRWSR')
	cCodVend:=cVendLogin
	cNomeVend:= HttpSession->Nome
	cItem := StrZero(1,TamSX3("CK_ITEM")[1])
	cCodOrc :=	'<input type="hidden" id="CJ_VEND" name="CJ_VEND" value="'+cVendLogin+'">'

	cCliente:='<select data-plugin-selectTwo class="form-control populate placeholder" data-plugin-options='+"'"
	cCliente+='{ "placeholder": "Selecione um Cliente", "allowClear": false }'+"'"+' name="CJ_CLIENTE" id="CJ_CLIENTE" '
	cCliente+='onchange="javascript:SelCliente()" required="" aria-required="true"> '
	cCliente+=' <option value=""> </option>'
	// Localiza os clientes
	cOptCli+= u_ListaCli(cVendLogin,"")
	cCliente+= cOptCli
	cCliente+='</select>'

	//Oportunidade
	cOport:='<select data-plugin-selectTwo class="form-control poulate placeholder mb-md" data-plugin-options='+"'"+'{"placeholder": "Selecione..."}'+"'"'
	cOport+=' name="CJ_NROPOR" id="CJ_NROPOR" onchange="javascript:atuRevOpt();">'
	cOport+='<option value=""></option>'
	//Busca a lista de oportunidades
	cOport+= u_ListaOpt(cVendLogin,"")
	cOport+='</select>'

	cRevOpt:= '<input id="CJ_REVISA" name="CJ_REVISA" class="form-control" value="" disabled>'


	//Combo da tabela de preço
	cTabPadrao:= GetNewPar("PR_TABPADR","001")
	cTabela:='<select data-plugin-selectTwo class="form-control populate placeholder" data-plugin-options='+"'"
	cTabela+='{ "placeholder": "Selecione", "allowClear": false }'+"'"+' name="CJ_TABELA" id="CJ_TABELA" '
	cTabela+='</select>'

	//Tabela de preço por filial
	cQry:= "SELECT DA0_CODTAB, DA0_DESCRI "
	cQry+= "FROM "+RetSqlName("DA0")+" DA0 "
	cQry+= "WHERE DA0_FILIAL = '"+xFilial("DA0")+"'
	cQry+= "AND DA0_ATIVO = '1' "
	cQry+= "AND (DA0_DATATE = '' OR DA0_DATATE >= '"+dtos(dDataBase)+"') "
	cQry+= "AND DA0.D_E_L_E_T_ = ' ' "
	If Select("QFIL") > 0
		QFIL->(dbCloseArea())
	Endif
	TcQuery cQry New Alias "QFIL"

	While QFIL->(!Eof())
		cTabela+='	<option value="'+Alltrim(QFIL->DA0_CODTAB)+'" '+Iif(QFIL->DA0_CODTAB == cTabPadrao,'selected','')+'>'+Alltrim(QFIL->DA0_CODTAB)+' - '+Alltrim(QFIL->DA0_DESCRI)+'</option>'
		QFIL->(dbSkip())
	End
	cTabela+='</select>'

	//Tipo de cliente
	aTpCli:= RetSx3Box(Posicione('SX3',2,'CJ_TIPOCLI','X3CBox()'),,,1)
	cTpCliente:='<select data-plugin-selectTwo class="form-control populate placeholder" data-plugin-options='+"'"
	cTpCliente+='{ "placeholder": "Selecione...", "allowClear": false }'+"'"+' name="CJ_TIPOCLI" id="CJ_TIPOCLI" '
	cTpCliente+=' disabled >'
	cTpCliente+=' <option value=""></option>'
	For f:= 1 to Len(aTpCli)
		cTpCliente+='	<option value="'+aTpCli[f,2]+'">'+aTpCli[f,3]+'</option>'
	Next
	cTpCliente+='</select>'

	//Grupo de tributação do cliente
	cGrpTrib:= '<input id="CJ_GRPTRIB" name="CJ_GRPTRIB" class="form-control" value="" disabled>'


	//Contato
	cContato:=	'		<input id="CJ_XCONTAT" name="CJ_XCONTAT" maxlength="'+cvaltochar(GetSX3Cache("CJ_XCONTAT","X3_TAMANHO"))+'" class="form-control text-uppercase" value="" disabled>'
	cContDDD:=	'		<input id="CJ_XCONDDD" name="CJ_XCONDDD" maxlength="'+cvaltochar(GetSX3Cache("CJ_XCONDDD","X3_TAMANHO"))+'" class="form-control only-numbers" value="" disabled>'
	cContTel:=	'		<input id="CJ_XCONTEL" name="CJ_XCONTEL" maxlength="'+cvaltochar(GetSX3Cache("CJ_XCONTEL","X3_TAMANHO"))+'" class="form-control only-numbers" value="" disabled>'


	//Cliente de Entrega
	cCliEntr:='<select class="form-control populate selectpicker" data-live-search="true"'
	cCliEntr+='title="Selecione..." name="CJ_CLIENT" id="CJ_CLIENT" disabled>'
	cCliEntr+=' <option data-hidden="true"></option>'
	cCliEntr+='</select>'

	//Local de entrega
	cLocalEnt:=	'<input id="CJ_UFENT" name="CJ_UFENT" class="form-control" value="" onchange="javascript:atuVlrFrete();" disabled>'

	//Nome da obra
	cObra:=	'<input id="CJ_OBRA" name="CJ_OBRA" maxlength="'+cvaltochar(GetSX3Cache("CJ_OBRA","X3_TAMANHO"))+'" class="form-control text-uppercase" value="" disabled>'

	//Status da Obra
	aStObra:= RetSx3Box(Posicione('SX3',2,'CJ_VEND6','X3CBox()'),,,1)
	cStatusObra:='<select data-plugin-selectTwo class="form-control poulate mb-md" data-plugin-options='+"'"+'{"placeholder": "Selecione...", "minimumResultsForSearch": "-1"}'+"'"'
	cStatusObra+=' name="CJ_VEND6" id="CJ_VEND6" disabled>'
	cStatusObra+='<option value=""></option>'
	For f:= 1 to Len(aStObra)
		cStatusObra+='	<option value="'+Left(aStObra[f,1],2)+'">'+aStObra[f,1]+'</option>'
	Next
	cStatusObra+='</select>'

	//Previsão Fechamento
	aPrevisao:= {{"B","Balizador"},{"A","30/120 dias"},{"V","Em 30 dias"},{"M","Após 4 meses"},{"C","Concorrência"}}
	cPrevFecha:='<select data-plugin-selectTwo class="form-control poulatemb-md" data-plugin-options='+"'"+'{"placeholder": "Selecione...", "minimumResultsForSearch": "-1"}'+"'"'
	cPrevFecha+=' name="CJ_TERMOME" id="CJ_TERMOME" disabled>'
	cPrevFecha+='<option value=""></option>'
	For f:= 1 to Len(aPrevisao)
		cPrevFecha+='	<option value="'+aPrevisao[f,1]+'">'+aPrevisao[f,2]+'</option>'
	Next
	cPrevFecha+='</select>'

	//Seleciona as condições de pagamento disponíveis no combo
	cCondPag:='<select data-plugin-selectTwo class="form-control populate placeholder mb-md" data-plugin-options='+"'" '
	cCondPag+='{ "placeholder": "Selecione...", "allowClear": false }'+"'"+' name="CJ_CONDPAG" id="CJ_CONDPAG" '
	cCondPag+='required="" aria-required="true" onchange="javascript:vldCond()" disabled>'

	cCondPag+='	<option value=""></option>'

	//Verifica a tabela cadastrada no cliente
	SE4->(dbSeek(xFilial("SE4")+SA1->A1_COND))

	cCondNot:= GetNewPar("PR_CONDPNO","")
	cCondPad:= GetNewPar("PR_CONDPAD","B13")

	//Seleciona as condições de pagamento disponíveis no combo
	cQry:= " Select E4_CODIGO, E4_DESCRI, E4_ACRSFIN"
	cQry+= " From "+RetSqlName("SE4")+" SE4 "
	cQry+= " Where E4_FILIAL = '"+xFilial("SE4")+"' "
	cQry+= " And E4_MSBLQL <> '1' "
	If !Empty(cCondNot)
		cQry+= " And E4_CODIGO not in "+FormatIn(cCondNot,"|")+" "
	Endif
	cQry+= " And SE4.D_E_L_E_T_ = ' ' "
	If Select("QRP") > 0
		QRP->(dbCloseArea())
	Endif
	TcQuery cqry New Alias "QRP"

	While QRP->(!Eof())
		cCondPag+='	<option value="'+QRP->E4_CODIGO+'" '+Iif(QRP->E4_CODIGO == cCondPad,'selected','')+'>'+Alltrim(QRP->E4_CODIGO)+" - "+Alltrim(QRP->E4_DESCRI)+'</option>'
		QRP->(dbSkip())
	End
	QRP->(dbCloseArea())

	cCondPag+='</select>'

	

	//Intermediador
	cIntermed:='<select class="form-control populate selectpicker" data-live-search="true"'
	cIntermed+='title="Selecione..." name="CJ_CLIINTE" id="CJ_CLIINTE" disabled>'
	cIntermed+=' <option data-hidden="true"></option>'
	cIntermed+='</select>'

	//Retorno
	nDiasVal:= 0
	cRetorno:='<input type="text" id="CJ_RETORNO" name="CJ_RETORNO" data-plugin-datepicker data-plugin-options='+"'"+'{ "startDate": "+'+cvaltochar(nDiasVal)+'d", "language": "pt-BR",'
	cRetorno+='"daysOfWeekDisabled": "[0]","daysOfWeekHighlighted":"[0]","autoclose": "true","disabled":"true"}'+"'"+' class="form-control only-numbers" placeholder="__/__/____" '
	cRetorno+='value="'+dtoc(date()+nDiasVal)+'" disabled>'

//Estudo Luminotécnico
	aEstd:= RetSx3Box(Posicione('SX3',2,'CJ_LUMINOT','X3CBox()'),,,1)
	aSort(aEstd)
	cEstudo:='<select data-plugin-selectTwo class="form-control poulatemb-md" data-plugin-options='+"'"+'{"placeholder": "Selecione...", "minimumResultsForSearch": "-1"}'+"'"'
	cEstudo+=' name="CJ_LUMINOT" id="CJ_LUMINOT" onchange="javascript:vldEstudo()" disabled>'
	cEstudo+='<option value=""></option>'
	For f:= 1 to Len(aEstd)
		cEstudo+='	<option value="'+aEstd[f,2]+'" >'+Upper(aEstd[f,3])+'</option>'
	Next
	cEstudo+='</select>'

	cNumEst:= '	<input id="CJ_REGLUMI" name="CJ_REGLUMI" maxlength="'+cvaltochar(GetSX3Cache("CJ_REGLUMI","X3_TAMANHO"))+'" class="form-control" value="" disabled>'

	//Segmento
	aSegmen:= RetSx3Box(Posicione('SX3',2,'CJ_SEGMENT','X3CBox()'),,,1)
	cSegmento:='<select data-plugin-selectTwo class="form-control poulatemb-md" data-plugin-options='+"'"+'{"placeholder": "Selecione...","minimumResultsForSearch": "-1"}'+"'"'
	cSegmento+=' name="CJ_SEGMENT" id="CJ_SEGMENT" disabled>'
	cSegmento+=' <option value=""></option>'
	For f:= 1 to Len(aSegmen)
		cSegmento+='	<option value="'+aSegmen[f,1]+'" >'+aSegmen[f,1]+'</option>'
	Next

	cSegmento+='</select>'

	//Prospecção
	aProsp:= RetSx3Box(Posicione('SX3',2,'CJ_PROPECC','X3CBox()'),,,1)
	cProsp:='<select data-plugin-selectTwo class="form-control poulatemb-md" data-plugin-options='+"'"+'{"placeholder": "Selecione...", "minimumResultsForSearch": "-1"}'+"'"'
	cProsp+=' name="CJ_PROPECC" id="CJ_PROPECC" onchange="javascript:vldProspec()" disabled>'
	cProsp+='<option value=""></option>'
	For f:= 1 to Len(aProsp)
		cProsp+='	<option value="'+aProsp[f,2]+'" >'+Upper(aProsp[f,3])+'</option>'
	Next
	cProsp+='</select>'

	//Prospectado Por
	aProsp:= RetSx3Box(Posicione('SX3',2,'CJ_PROSCOD','X3CBox()'),,,1)
	aSort(aProsp)
	cProspPor:='<select data-plugin-selectTwo class="form-control poulatemb-md" data-plugin-options='+"'"+'{"placeholder": "Selecione...","minimumResultsForSearch": "-1"}'+"'"'
	cProspPor+=' name="CJ_PROSCOD" id="CJ_PROSCOD" onchange="javascript:vldProsPor();" disabled>'
	cProspPor+=' <option value=""></option>'
	For f:= 1 to Len(aProsp)
		cProspPor+='	<option value="'+aProsp[f,1]+'">'+aProsp[f,1]+'</option>'
	Next
	cProspPor+='</select>'


	//Regional
	cRegional:='<select data-plugin-selectTwo class="form-control populate placeholder mb-md" data-plugin-options='+"'" '
	cRegional+='{ "placeholder": "Selecione...", "allowClear": false }'+"'"+' name="CJ_REGIAO" id="CJ_REGIAO" '
	cRegional+='required="" aria-required="true" disabled>'
	cRegional+='<option value=""></option>'
	cRegional+= u_ListaVend(.T.,Posicione("SA3",1,xFilial("SA3")+cVendLogin,"A3_REGIONA"))
	cRegional+='</select>'

	//Vendedor do cliente
	cVend2:= '<select data-plugin-selectTwo class="form-control populate placeholder" data-plugin-options='+"'" '
	cVend2+='{ "placeholder": "Selecione...", "allowClear": false }'+"'"+' name="CJ_VEND" id="CJ_VEND" '
	cVend2+='disabled>' //required="" aria-required="true"
	cVend2+='<option value=""></option>'
	cVend2+= u_ListaVend(.F.,SA1->A1_VEND)
	cVend2+='</select>'

	//Vendedor da oportunidade
	cVend3:= '<select data-plugin-selectTwo class="form-control populate placeholder mb-md" data-live-search="true" data-plugin-options='+"'" 
	cVend3+='{ "placeholder": "Selecione...", "allowClear": false }'+"'"+' name="CJ_VEND3" id="CJ_VEND3" disabled>'//required="" aria-required="true" 
	cVend3+='<option value="">Selecione...</option>'
	//cVend3+= u_ListaVend(.F.,SA1->A1_VEND)
	cVend3+='</select>'

	//Vendedor 4
	cVend4:= '<select data-plugin-selectTwo class="form-control populate placeholder mb-md" data-plugin-options='+"'" '
	cVend4+='{ "placeholder": "Selecione...", "allowClear": false }'+"'"+' name="CJ_VEND4" id="CJ_VEND4" '
	cVend4+=' disabled>' //required="" aria-required="true"
	cVend4+='<option value=""></option>'
	cVend4+= u_Vend04('')
	cVend4+='</select>'

	//Especificado por
	cEspecif:= '<select data-plugin-selectTwo class="form-control populate placeholder mb-md" data-plugin-options='+"'" '
	cEspecif+='{ "placeholder": "Selecione...", "allowClear": false }'+"'"+' name="CJ_CODESP" id="CJ_CODESP" '
	cEspecif+='disabled>' //required="" aria-required="true" 
	cEspecif+='<option value=""></option>'
	cEspecif+= u_ListaEsp('')
	cEspecif+='</select>'

	//Negociadora
	cNegociad:= '<select data-plugin-selectTwo class="form-control populate placeholder mb-md" data-plugin-options='+"'" '
	cNegociad+='{ "placeholder": "Selecione...", "allowClear": false }'+"'"+' name="CJ_VEND7" id="CJ_VEND7" '
	cNegociad+='disabled>' //required="" aria-required="true" 
	cNegociad+='<option value=""></option>'
	cNegociad+= u_ListaNeg('')
	cNegociad+='</select>'

	
	//Validade do Orçamento
	nDiasVal:= GetNewPar("PR_DTVALID",10)
	cValidade:='<input type="text" id="CJ_VALIDA" name="CJ_VALIDA" data-plugin-datepicker data-plugin-options='+"'"+'{ "startDate": "+'+cvaltochar(nDiasVal)+'d", "language": "pt-BR",'
	cValidade+='"daysOfWeekDisabled": "[0]","daysOfWeekHighlighted":"[0]","autoclose": "true","disabled":"true"}'+"'"+' class="form-control only-numbers" placeholder="__/__/____" '
	cValidade+='value="'+dtoc(date()+nDiasVal)+'" disabled>'

	//Prazo de embarque
	cPrazoEmb:= '<input id="CJ_PRZEMB" name="CJ_PRZEMB" maxlength="'+cvaltochar(GetSX3Cache("CJ_PRZEMB","X3_TAMANHO"))+'" class="form-control" value="15" disabled>'


	//Tipo de frete
	aTpFrete:= {{"S","Sem Frete"},{"C","CIF"},{"F","FOB"}}
	cTpFrete:='<select data-plugin-selectTwo class="form-control poulatemb-md" data-plugin-options='+"'"+'{"minimumResultsForSearch": "-1"}'+"'"'
	cTpFrete+=' name="CJ_TPFRETE" id="CJ_TPFRETE" onchange="javascript:VldFrete()" disabled>'
	For f:= 1 to Len(aTpFrete)
		cTpFrete+='	<option value="'+aTpFrete[f,1]+'" >'+aTpFrete[f,2]+'</option>'
	Next
	cTpFrete+='</select>'

	cPFrete:= '<input id="CJ_PERCFRT" name="CJ_PERCFRT" class="form-control text-right percentual" placeholder="0,00" maxlength="'+cvaltochar(GetSX3Cache("CJ_PERCFRT","X3_TAMANHO"))+'" '
	cPFrete+= 'value="" disabled>'

	cValFre:= '<input id="CJ_FRETE" name="CJ_FRETE" class="form-control money text-right" placeholder="0,00" '
	cValFre+= 'value="" disabled>'

	//% RT
	cComRT:= '<input id="CJ_COMISTR" name="CJ_COMISTR" class="form-control percentual text-right" placeholder="0,00" maxlength="'+cvaltochar(GetSX3Cache("CJ_COMISTR","X3_TAMANHO"))+'" '
	cComRT+= 'value="" disabled>'

	//Observação Comercial
	cObsCom:= ""


	//Margem de Contribuição
	If HttpSession->Tipo <> "R" //Representante
		cMargemCont:= '	<div class="col-lg-2"> '
		cMargemCont+= '		<label class="control-label">MC</label> '
		cMargemCont+= '		<input id="MARGEM" name="MARGEM" class="form-control" value="" disabled >'//'+u_getMCOrc() + "%"+'
		cMargemCont+= '	</div>'
	Endif

/*
//Transportadora
	cTransp:='<select data-plugin-selectTwo class="form-control populate placeholder mb-md" data-plugin-options='+"'" '
	cTransp+='{ "placeholder": "Selecione uma Transportadora", "allowClear": false }'+"'"+' name="CJ_XTRANSP" id="CJ_XTRANSP" '
	cTransp+='required="" aria-required="true" disabled>'
	cTransp+='	<option value=""></option>'
	cTransp+='</select>'

//Modalidades - Forma de Pagamento
	//aModali:= {{"",""},{"B","Boleto"},{"P","PIX"},{"C","Cartão de crédito"}}
	cModali:= '<select data-plugin-selectTwo class="form-control populate mb-md" name="CJ_XMODALI" id="CJ_XMODALI" required="" aria-required="true" '
	cModali+= 'onchange="javascript:condPag()">'
	SX5->(dbSeek(xFilial("SX5")+'ZE'))
	While SX5->(!Eof() .and. SX5->X5_TABELA = 'ZE')
		cModali+='	<option value="'+Alltrim(SX5->X5_CHAVE)+'">'+Alltrim(SX5->X5_DESCRI)+'</option>'
		SX5->(dbSkip())
	End
	cModali+='</select>'


//Seleciona as condições de pagamento disponíveis no combo
	cCondPag:='<select data-plugin-selectTwo class="form-control populate placeholder mb-md" data-plugin-options='+"'" '
	cCondPag+='{ "placeholder": "Selecione...", "allowClear": false }'+"'"+' name="CJ_CONDPAG" id="CJ_CONDPAG" '
	cCondPag+='required="" aria-required="true" onchange="javascript:vldCond()">'
	cCondPag+='	<option value=""></option>'
	cCondPag+='</select>'



//Peso
	cPeso:= '<input type="text" id="CJ_XPESO" name="CJ_XPESO" class="form-control text-right only-numbers" placeholder="0" '
	cPeso+= 'value="">'

//Volume
	cVolume:= '<input type="text" id="CJ_XVOLUME" name="CJ_XVOLUME" class="form-control text-right only-numbers" placeholder="0" '
	cVolume+= 'value="">'

//Espécie
	cEspecie:= '<input type="text" id="CJ_XESPECI" name="CJ_XESPECI" class="form-control" placeholder="" '
	cEspecie+= 'value="" maxlength="10">'

//Itens do orçamento
/*
	aItens - array que define o cabeçalho da tabela de produtos
	[1] - Nome da coluna
	[2] - Nome do campo
	[3] - Tamanho
	[4] - Alinhamento
	[5] - Tipo
	[6] - Editável
	[7] - Obrigatório
	[8] - Moeda
	[9] - Placeholder
	[10] - Hidden
	[11] - MaxLength
*/
	aAdd(aItens, {"Item","CK_ITEM","*","text-left","C",.F.,.F.,.F.,"",.F.,""})
	aAdd(aItens, {"Produto","CK_PRODUTO","300px"," text-left","C",.T.,.T.,.F.,"Selecione...",.F.,""})
	aAdd(aItens, {"Quant.","CK_QTDVEN","*"," text-right","N",.T.,.T.,.F.,"0",.F.,""})
	aAdd(aItens, {"Observação","CK_OBS","*"," text-left","C",.T.,.T.,.F.,"",.F.,""})
	aAdd(aItens, {"Prazo de Embarque","CK_PRZEMB","70px","text-right","N",.F.,.F.,.F.,"",.F.,""})
	aAdd(aItens, {"Vlr Unitário","CK_PRCVEN","*"," text-right","N",.T.,.F.,.T.,"0,00",.F.,""})
	aAdd(aItens, {"Vlr c/ Impostos","CK_XPRCIMP","*","text-right","N",.F.,.F.,.T.,"0,00",.T.,""})
	aAdd(aItens, {"Vlr de Venda","iCK_PRCVEN","*"," text-right myformato","N",.F.,.F.,.T.,"0,00",.T.,""})
	//aAdd(aItens, {"IPI","CK_XVALIPI","*"," text-right","N",.T.,.F.,.T.,"0,00",.T.,""})
	//aAdd(aItens, {"ICMS","CK_XVALICM","*"," text-right","N",.T.,.F.,.T.,"0,00",.T.,""})
	//aAdd(aItens, {"ICMS ST","CK_XICMST","*"," text-right","N",.T.,.F.,.T.,"0,00",.T.,""})
	aAdd(aItens, {"% Desconto","CK_DESCONT","*"," text-right percentual","N",.T.,.F.,.T.,"0,00",Iif(HttpSession->Tipo <> "R",.F.,.T.) ,"7"})
	aAdd(aItens, {"% Comissão","PER_COM","*"," text-right ","N",.F.,.F.,.T.,"0,00",.T.,""})
	aAdd(aItens, {"Vlr Comissão","VAL_COM","*"," text-right","N",.T.,.F.,.T.,"0,00",.T.,""})
	aAdd(aItens, {"Total","CK_VALOR","150px"," text-right","N",.F.,.F.,.T.,"0,00",.F.,""})
	aAdd(aItens, {"","ACAO","*"," text-center","X",.T.,.F.,.F.,"",.F.,""})

// Cria o cabeçalho dos Itens
	For nLin := 1 to Len(aItens)
		cOrcCabec += '<th'+Iif(aItens[nLin,2] == "CK_VALOR",' width="'+aItens[nLin,3]+'"',Iif(aItens[nLin,2] == "CK_PRODUTO",' width="'+aItens[nLin,3]+'"',''))
		cOrcCabec+= Iif(aItens[nLin,10],' hidden','')+'>'+aItens[nLin][1]+'</th>'
	Next

//Preenchimento dos itens
	nItens++
	cOrcItens += '<tr class="odd" id="linha01">'
	For nLin := 1 to Len(aItens)

		If aItens[nLin,2] == "ACAO"
			cOrcItens += '<td class="actions">'
			cOrcItens += '	<i class="fa fa-info fa-lg" data-toggle="tooltip" data-original-title="Detalhes da linha" onclick="detalheOrc('+"'"+cItem+"'"+');"></i>'
			cOrcItens += '  <i class="fa fa-times-circle fa-lg" data-toggle="tooltip" data-original-title="Remover a linha" onclick="removeItem('+"'"+cItem+"'"+');"></i>
			cOrcItens += '</td>
		Else
			If aItens[nLin,2] == "CK_PRODUTO"
				cOrcItens += '<td>' //class="form-group row pb-4"
			Else
				cOrcItens += '<td'+Iif(aItens[nLin,10],' hidden','')+'>'
			Endif
			lMoeda:= aItens[nLin,8] //Indica se é Moeda
			lNumber:= aItens[nLin,5] = "N" //Indica que é numérico
			xValue:= ""
			Do Case
			Case aItens[nLin][5] == 'C'
				If aItens[nLin,2] == "CK_ITEM"
					xValue := "01"
				Else
					xValue := space(GetSX3Cache(aItens[nLin][2],"X3_TAMANHO"))
				Endif
			Case aItens[nLin][5] == 'N'
				If aItens[nLin,2] == "CK_QTDVEN"
					xValue := Iif(lNewOrc,"0",Alltrim(PadR(TransForm(QRY->&(aItens[nLin][2]),PesqPict("SCK",aItens[nLin,2])),space(GetSX3Cache(aItens[nLin][2],"X3_TAMANHO")))))
				ElseIf aItens[nLin,2] == "PER_COM"
					xValue := Iif(lNewOrc,"0",Alltrim(PadR(TransForm(QRY->&(aItens[nLin][2]),PesqPict("SD2","D2_COMIS1")),space(GetSX3Cache(aItens[nLin][2],"X3_TAMANHO")))))
				ElseIf aItens[nLin,2] == "VAL_COM"
					xValue := Iif(lNewOrc,"0",Alltrim(PadR(TransForm(QRY->&(aItens[nLin][2]),PesqPict("SCK","CK_PRCVEN")),space(GetSX3Cache(aItens[nLin][2],"X3_TAMANHO")))))
				Elseif aItens[nLin,2] == "iCK_PRCVEN"
					xValue := Iif(lNewOrc,"0",Alltrim(PadR(TransForm(QRY->&(aItens[nLin][2]),PesqPict("SCK","CK_PRCVEN")),space(GetSX3Cache(aItens[nLin][2],"X3_TAMANHO")))))
				Else
					xValue := Iif(lNewOrc,"0",Alltrim(PadR(TransForm(QRY->&(aItens[nLin][2]),PesqPict("SCK",aItens[nLin,2])),space(GetSX3Cache(aItens[nLin][2],"X3_TAMANHO")))))
				Endif
			EndCase

			If aItens[nLin,6] //Campo Editável
				If aItens[nLin,2] == "CK_PRODUTO"
					//Cria o select para o produto
					/*
					cOrcItens +='<select class="selectpicker" name="CK_PRODUTO'+cItem+'" id="CK_PRODUTO'+cItem+'" '
					cOrcItens += Iif(aItens[nLin][7],'required="" aria-required="true" ','')+' data-live-search="true" '
					cOrcItens +='onchange="javascript:gatProduto($(this))" data-width="290px" value="">' //style="size:4" data-width="90%" style="height:90%"
					cOrcItens +='	<option value="">Selecione...</option>'
					cOrcItens+='</select>'
					*/
/*
					cOrcItens +='<div class="input-group input-group-icon">'
					cOrcItens +='<input type="text" class="form-control text-uppercase" placeholder="Digite o código ou descrição..." '
					cOrcItens +='name="CK_PRODUTO'+cItem+'" id="CK_PRODUTO'+cItem+'"'
					cOrcItens += Iif(aItens[nLin][7],'required="" aria-required="true" ','')+' data-live-search="true" '
					cOrcItens +='value="" autocomplete="off"/>'

					cOrcItens +='	<span class="input-group-addon">'
					//cOrcItens +='		<span class="btn" type="button" id="btSearch'+cItem+'" onclick="javascript:getProduto($(this));">
					cOrcItens +='		<span class="icon">'
					cOrcItens +='			<a class="btn" type="button" id="btSearch" onclick="javascript:getProduto($(this));">
					cOrcItens +='				<i class="fa fa-search"></i>'
					cOrcItens +='			</a>'
					//cOrcItens +='		</span>'
					cOrcItens +='	</span>'
					cOrcItens +='</div>'
*/

					cOrcItens +='<div class="form-group">'
					cOrcItens +='	<div class="col-md-12">
					cOrcItens +='		<div class="flexContainer">
					cOrcItens +='			<input type="text" class="form-control smsediticon" placeholder="Digite o código ou descrição..." '
					cOrcItens +='			name="CK_PRODUTO'+cItem+'" id="CK_PRODUTO'+cItem+'"'
					cOrcItens += 			Iif(aItens[nLin][7],'required="" aria-required="true" ','')+' data-live-search="true" '
					cOrcItens +='			value="" autocomplete="off"/>'

					cOrcItens +='			<button class="btSearch" id="btSearch'+cItem+'" onclick="javascript:getProduto($(this));">'
					cOrcItens +='				<i class="fa fa-search" alt="Pesquisar"></i>'
					//cOrcItens +='				<img src="\imagens\lupa.png" alt="Pesquisar">'
					cOrcItens +='			</button>
					cOrcItens +='		</div>
					cOrcItens +='	</div>
					cOrcItens +='</div>

				Else
					cOrcItens += '<input id="'+aItens[nLin][2]+cItem+'" data-prop="'+aItens[nLin][2]+'" name="'+aItens[nLin][2]+cItem+'" class="form-control '+aItens[nLin,4]
					cOrcItens +=If(lMoeda," ",If(lNumber," only-numbers",""))+'" type="text" '
//					cOrcItens +=If(lMoeda," money5",If(lNumber," only-numbers",""))+'" type="text" '
					cOrcItens += 'placeholder="'+aItens[nLin,9]+'" '
					//Atribui as funções javascript
					If aItens[nLin,2] == "CK_QTDVEN"
						cOrcItens+='onblur="javascript:VldQtd('+"'"+cItem+"'"+') "'
					Endif
					If aItens[nLin,2] == "iCK_PRCVEN"
						cOrcItens+='onblur="javascript:VldValor('+"'"+cItem+"'"+') "'
					Endif

					If aItens[nLin,2] == "CK_DESCONT"
						cOrcItens+='onblur="javascript:VldValor('+"'"+cItem+"'"+')" maxlength="7" '
						//cOrcItens+='onkeyup="formate()" onblur="javascript:VldValor('+"'"+cItem+"'"+') "'
					Endif

					If aItens[nLin,2] $ ("CK_QTDVEN|iCK_PRCVEN|CK_DESCONT")
						cOrcItens+='onkeyup="javascript:TotalItem('+"'"+cItem+"'"+') "'
					Endif

					//Campo obrigatório
					cOrcItens += Iif(aItens[nLin][7],'required="" aria-required="true" ','')
					//Inicia todos os campos desabilitados
					cOrcItens += 'disabled '
					cOrcItens += 'value="'+Alltrim(xValue)+'">'
				Endif


			Else
				cOrcItens += '<input id="'+aItens[nLin][2]+cItem+'" data-prop="'+aItens[nLin][2]+'" name="'+aItens[nLin][2]+cItem+'" class="form-control '+aItens[nLin,4]+' input-block" '
				If aItens[nLin,2] = "CK_ITEM"
					cOrcItens += ' size=4 '
				Endif
				cOrcItens += 'type="text" disabled width="" '
				cOrcItens += 'value="'+Alltrim(xValue)+'">'
			Endif
		Endif

		cOrcItens += '</td>'
	Next

//Inputs Hidden
	cItensHid += '<input type="hidden" class="" id="ALIQ_ICMS'+cItem+'" name="ALIQ_ICMS'+cItem+'" value="0">'
	cItensHid += '<input type="hidden" class="" id="ALIQ_IPI'+cItem+'" name="ALIQ_IPI'+cItem+'" value="0">'
	cItensHid += '<input type="hidden" class="" id="ALIQ_ST'+cItem+'" name="ALIQ_ST'+cItem+'" value="0">'
	cItensHid += '<input type="hidden" class="" id="VAL_ICMS'+cItem+'" name="VAL_ICMS'+cItem+'" value="0">'
	cItensHid += '<input type="hidden" class="" id="VAL_IPI'+cItem+'" name="VAL_IPI'+cItem+'" value="0">'
	cItensHid += '<input type="hidden" class="" id="VAL_ST'+cItem+'" name="VAL_ST'+cItem+'" value="0">'
	cItensHid += '<input type="hidden" class="" id="BASE_ICMS'+cItem+'" name="BASE_ICMS'+cItem+'" value="0">'
	cItensHid += '<input type="hidden" class="" id="BASE_ST'+cItem+'" name="BASE_ST'+cItem+'" value="0">'
	cItensHid += '<input type="hidden" class="" id="BASE_IPI'+cItem+'" name="BASE_IPI'+cItem+'" value="0">'
	cItensHid += '<input type="hidden" class="" id="QTD_EMB'+cItem+'" name="QTD_EMB'+cItem+'" value="0">'
	cItensHid += '<input type="hidden" class="" id="CK_TES'+cItem+'" name="CK_TES'+cItem+'" value="">'
	cItensHid += '<input type="hidden" class="" id="QTDMIN'+cItem+'" name="QTDMIN'+cItem+'" value="">'
	cOrcItens+=cItensHid
	cOrcItens += '</tr>'

	cOrcItens += '<input type="hidden" name="QtdItens" id="QtdItens" value="'+cValtoChar(nItens)+'"/>'
	cOrcItens += '<input type="hidden" id="PROXIMO" name="PROXIMO" value="01"/>
	cOrcItens += '<input type="hidden" name="CJ_NUM" id="CJ_NUM" value="" />'
	cOrcItens += '<input type="hidden" name="OPCAO" id="OPCAO" value="3" />'

//Adiciona os botões de ações na tabela de itens
	cBtnItens+='<div class="row form-group">'
	cBtnItens+='	<div class="col-sm-2">'
	cBtnItens+='		<button class="btn btn-primary" id="btAddItm" name="btAddItm">'
	cBtnItens+='			<i class="fa fa-plus-square"></i> Novo Item</button>'
	cBtnItens+='	</div>'
	cBtnItens+='</div>'


//Adiciona os botões da página
	//cBotoes+='<h5 class="text-primary">Orçamento válido apenas dentro do mês de '+MesExtenso(date())+' de '+cvaltochar(Year(date()))+'.</h5>'
	cBotoes+='<input class="btn btn-primary" type="button" id="btSalvar" name="btSalvar" value="Salvar"/>'+chr(13)+chr(10)
	cBotoes+='<input class="btn btn-primary" type="button" id="btVoltar" name="btVoltar" value="Voltar" onclick="javascript: location.href='+"'"+'u_orcamento.apw?PR='+cCodLogin+"';"+'"/>'+chr(13)+chr(10)

//Retorna o HTML para construção da página
	cHtml := H_AddOrc()

	Web Extended End

Return (cHTML)

/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ ListaVend   ¦ Autor ¦ Lucilene Mendes     ¦ Data ¦24.08.24 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Retorna lista de select com os vendedores conforme o tipo  ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯*/
User Function ListaVend(lRegional,cOpcSel)
Local cLista:= ""
Default lRegional:= .F.

cQry:= " Select A3_COD, A3_NOME "
cQry+= " From "+RetSqlName("SA3")+" SA3 "
cQry+= " Where A3_FILIAL = '"+xFilial("SA3")+"' "
If lRegional
	cQry+= " And A3_CLASSIF = 'R' "
	cQry+= " And SUBSTRING(A3_NOME,1,4) = 'REGI' "
Else
	cQry+= " And A3_CLASSIF <> 'R' "
	cQry+= " And SUBSTRING(A3_NOME,1,4) <> 'REGI' "
Endif
cQry+= " And A3_MSBLQL <> '1' "
cQry+= " And SA3.D_E_L_E_T_ = ' ' "
If Select("QRR") > 0
	QRR->(dbCloseArea())
Endif
conout("query vendedores:"+cqry)
APWExOpenQuery(ChangeQuery(cQry),'QRR',.T.)

While QRR->(!Eof())
	cLista+='	<option value="'+QRR->A3_COD+'"'+Iif(Alltrim(QRR->A3_COD) == AllTrim(cOpcSel),'selected','')+'>'+Alltrim(QRR->A3_COD)+" - "+Alltrim(u_RemEspec(QRR->A3_NOME))+'</option>'
	QRR->(dbSkip())
End
QRR->(dbCloseArea())


Return cLista

/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ Vend04	   ¦ Autor ¦ Lucilene Mendes     ¦ Data ¦24.08.24 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Retorna lista de select com os vendedores 04				  ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯*/
User Function Vend04(cOpcSel)
Local cLista:= ""
Local cCodVend:= GetNewPar("PR_VEND04","000845/000846")

cQry:= " Select A3_COD, A3_NOME "
cQry+= " From "+RetSqlName("SA3")+" SA3 "
cQry+= " Where A3_FILIAL = '"+xFilial("SA3")+"' "
cQry+= " And A3_COD IN "+FormatIn(cCodVend,"/")+" "
cQry+= " And A3_MSBLQL <> '1' "
cQry+= " And SA3.D_E_L_E_T_ = ' ' "
APWExOpenQuery(ChangeQuery(cQry),'QRV',.T.)

While QRV->(!Eof())
	cLista+='	<option value="'+QRV->A3_COD+'"'+Iif(Alltrim(QRV->A3_COD) == AllTrim(cOpcSel),'selected','')+'>'+Alltrim(QRV->A3_COD)+" - "+Alltrim(u_RemEspec(QRV->A3_NOME))+'</option>'
	QRV->(dbSkip())
End
QRV->(dbCloseArea())

Return cLista


/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ ListaEsp	   ¦ Autor ¦ Lucilene Mendes     ¦ Data ¦24.08.24 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Retorna lista de select com os especificadores			  ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯*/
User Function ListaEsp(cOpcSel)
Local cLista:= ""

cQry:= " Select X5_CHAVE, X5_DESCRI "
cQry+= " From "+RetSqlName("SX5")+" SX5 "
cQry+= " Where X5_FILIAL = '"+xFilial("SX5")+"' "
cQry+= " And X5_TABELA = 'Z1' "
cQry+= " And SX5.D_E_L_E_T_ = ' ' "
APWExOpenQuery(ChangeQuery(cQry),'QRX',.T.)

While QRX->(!Eof())
	cLista+='	<option value="'+QRX->X5_CHAVE+'"'+Iif(Alltrim(QRX->X5_CHAVE) == AllTrim(cOpcSel),'selected','')+'>'+Alltrim(QRX->X5_CHAVE)+" - "+Alltrim(u_RemEspec(QRX->X5_DESCRI))+'</option>'
	QRX->(dbSkip())
End
QRX->(dbCloseArea())

Return cLista

/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ ListaCli       ¦ Autor ¦ Lucilene Mendes ¦ Data ¦ 17.10.23 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Busca a lista de clientes ativos							  ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯*/
User Function ListaCli(cCodVend,cSelecionado)
Local cQuery:= ""
Local cLista:= ""

cQuery := " Select A1_COD, A1_LOJA, A1_CGC, A1_NOME, A1_TIPO, A1_CODMUN, A1_MUN, A1_COND "
cQuery += " From "+RetSqlName("SA1")+" SA1 "
cQuery += " Where A1_FILIAL = '"+xFilial("SA1")+"' "

cQuery += " AND ( "

If HttpSession->Tipo = 'S' //Supervisor acessa todos os clientes da sua equipe
	cQuery+= " A1_REGIAO = '"+HttpSession->Regional+"' "
	//cQuery+= " A1_VEND in "+FormatIn(HttpSession->Equipe,"|")+" "
Else
	If !Empty(cCodVend)
		cQuery+= " A1_VEND = '"+cCodVend+"'" // OR A1_VEND2 = '"+cCodVend+"'  OR A1_VEND3= '"+cCodVend+"' OR A1_VEND4= '"+cCodVend+"' OR A1_VEND5 = '"+cCodVend+"' ) "
	Else
		cQuery+= " A1_VEND <> '' "
	Endif
Endif

cQuery += " OR A1_VEND = ' ' )"

cQuery += " And A1_MSBLQL <> '1' "
cQuery += " And SA1.D_E_L_E_T_ = ' ' "
cQuery += " Order by A1_NOME "
conout("query clientes:"+cquery)

If Select("QRY") > 0
	QRY->(dbCloseArea())
Endif
APWExOpenQuery(ChangeQuery(cQuery),'QRY',.T.)

While QRY->(!EOF())
	cLista+='	<option value="'+Alltrim(QRY->A1_COD+QRY->A1_LOJA)+'" '+Iif(&(cSelecionado),'selected','')+'>'+QRY->A1_COD+'/'+QRY->A1_LOJA+' - '+Alltrim(u_RemEspec(QRY->A1_NOME))+" - "+Alltrim(QRY->A1_CGC)+'</option>'
	QRY->(dbSkip())
End
APWExCloseQuery('QRY')

Return cLista


/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ ListaOpt       ¦ Autor ¦ Lucilene Mendes ¦ Data ¦ 17.10.23 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Busca a lista de oportunidades							  ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯*/
User Function ListaOpt(cCodVend,cSelecionado)
Local cQuery:= ""
Local cLista:= ""

cQuery := " Select AD1_NROPOR,AD1_REVISA, AD1_DESCRI, AD1_DESCCI, AD1_NOMPAR"
cQuery += " From "+RetSqlName("AD1")+" AD1 "
cQuery += " Where AD1_FILIAL = '"+xFilial("AD1")+"' "
//cQuery += " And AD1_HOMOLO = '3' " //Status homologação = homologado
cQuery += " And AD1.D_E_L_E_T_ = ' ' "
cQuery += " Order by AD1_NROPOR "
conout("query oportunidade:"+cquery)
If Select("QRYAD1") > 0
	QRYAD1->(dbCloseArea())
Endif
APWExOpenQuery(ChangeQuery(cQuery),"QRYAD1",.T.)

While QRYAD1->(!EOF())
	cLista+='<option value="'+Alltrim(QRYAD1->AD1_NROPOR)+'">'+QRYAD1->AD1_NROPOR+'/'+Alltrim(QRYAD1->AD1_REVISA)+'/'+;
				Alltrim(u_RemEspec(QRYAD1->AD1_DESCRI))+'/'+Alltrim(u_RemEspec(QRYAD1->AD1_DESCCI))+'/'+Alltrim(u_RemEspec(QRYAD1->AD1_NOMPAR))+'</option>'

	QRYAD1->(dbSkip())
End
APWExCloseQuery('QRYAD1')

Return cLista

/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ ListaNeg	   ¦ Autor ¦ Lucilene Mendes     ¦ Data ¦24.08.24 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Retorna lista de select com os negociadores				  ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯*/
User Function ListaNeg(cOpcSel)
Local cLista:= ""

cQry:= " Select Z68_COD, Z68_NOME "
cQry+= " From "+RetSqlName("Z68")+" Z68 "
cQry+= " Where Z68_FILIAL = '"+xFilial("Z68")+"' "
cQry+= " And Z68_MSBLQL <> '1' "
cQry+= " And Z68.D_E_L_E_T_ = ' ' "
APWExOpenQuery(ChangeQuery(cQry),'QRN',.T.)

While QRN->(!Eof())
	cLista+='	<option value="'+QRN->Z68_COD+'"'+Iif(Alltrim(QRN->Z68_COD) == AllTrim(cOpcSel),'selected','')+'>'+Alltrim(QRN->Z68_COD)+" - "+Alltrim(u_RemEspec(QRN->Z68_NOME))+'</option>'
	QRN->(dbSkip())
End
QRN->(dbCloseArea())

Return cLista


/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ RemEspec    ¦ Autor ¦ Lucilene Mendes     ¦ Data ¦17.08.17 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Remove caracteres especiais								  ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/
User Function RemEspec(cTexto)
Local aNoChar:= {'<','>','+',"'"} //,"'",'"','&','+'}
Local i:= 0

For i:= 1 to Len(aNoChar)
	If aNoChar[i] $ cTexto
		cTexto:= StrTran(cTexto,aNoChar[i],"")
	Endif
Next


Return cTexto

/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ SlvOrc      ¦ Autor ¦ Lucilene Mendes     ¦ Data ¦17.08.17 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Gera a cotação.											  ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/
User Function SlvOrc()
	Local cHtml
	Local nOpc		:= 3 // 3- Incluir / 4- Alterar / 5- Excluir
	Local cCondPag	:= ""
	Local cTabela	:= ""
	Local cCliente	:= ""
	Local cLoja		:= ""
	Local cMsg		:= ""
	Local cTransp	:= ""
	Local cSerieNF	:= ""
	Local cModalidade:= ""
	Local dValidade	:= ""
	Local cItens	:= ""
	Local cDestOrc	:= ""
	Local cMsgIn	:= ""
	Local x			:= 0
	Local i			:= 0
	Local nTotSck	:= 0
	Local nPosLin	:= 0
	Local nDesc1	:= 0
	Local cDirOrc 	:= "\anexosPortal\orcamento\"
	Local cDirErro  := "\erro\"
	Local aItens	:= {}
	Local cNumSCJ	:= ""
	Local lRet		:= .T.
	Local cSaveVend
	local lEnvEmail := .f.
	Private cReturn
	Private aCabSCJ :={}
	Private aItemSCJ:={}
	Private aLinhaSCJ:={}
	Private lMsErroAuto:= .F.
	Private cCodLogin := ""
	Private cVendLogin:= ""

	Web Extended Init cHtml Start U_inSite()

	cVendLogin := u_GetUsrPR()
	cCodLogin  := U_SetParPR(cVendLogin)

	//Verifica se não perdeu a sessão
	If type("HttpSession->CodVend") = "U" .or. Empty(HttpSession->CodVend)
		conout(Procname()+"("+ltrim(str(procline()))+") *** Portal "+"Sessao encerrada")
		cHtml:= '<META HTTP-EQUIV="Refresh" CONTENT="0 ; URL=U_SMSPortal.apw">'
		return cHtml
	Endif

	//Verifica se existe pedido lançado para o cliente nos últimos 3 minutos.
    /*
	If Empty(HttpPost->CJ_NUM)
	    cQry:= "Select * from "+RetSqlName("SCJ")+" SCJ "
	    cQry+= "Where CJ_FILIAL = '"+xFilial("SCJ")+"' "
	    cQry+= "And CJ_CLIENTE = '"+Left(HttpPost->CJ_CLIENTE,9)+"' "
	    cQry+= "And CJ_LOJA = '"+Right(HttpPost->CJ_CLIENTE,4)+"' "
	    cQry+= "And CJ_EMISSAO = '"+dtos(dDataBase)+"' "
	    cQry+= "And CJ_COTCLI >= '"+StrTran(StrZero(SubHoras(Time(),'00:03:00'),5,2),'.',':')+":00"+"' "
	    cQry+= "And SCJ.D_E_L_E_T_ = ' ' "
	    If Select("QRH") > 0
			QRH->(dbCloseArea())
		Endif
		conout("Hora: "+Time()+" Vend: "+HttpSession->CodVend+" --> "+cqry)
		APWExOpenQuery(ChangeQuery(cQry),'QRH',.T.)
		If Contar("QRH","!Eof()") > 0
			cHtml:= ""
			Return cHtml
		Endif
    Endif
	*/
//Variáveis do cabeçalho
	cCondPag:= HttpPost->CJ_CONDPAG
	nDesc1:= Iif(Type("HttpPost->CJ_DESC1") <> "U",Val(HttpPost->CJ_DESC1),0)
	cTabela:= HttpPost->CJ_TABELA
	nTotSck := val(HttpPost->PROXIMO)
	cCliente:= Left(HttpPost->CJ_CLIENTE,6)
	cLoja:= Right(HttpPost->CJ_CLIENTE,6)
	cTransp:= Iif(Type("HttpPost->CJ_XTRANSP") <> "U",HttpPost->CJ_XTRANSP,"")
	//dDtEntreg := CTOD(HttpPost->CK_ENTREG)
	dValidade:= ctod(HttpPost->CJ_VALIDA)
	cSerieNF:= Iif(Type("HttpPost->CJ_XSERIEN") <> "U",HttpPost->CJ_XSERIEN,"")
	cTipoFrete := HttpPost->CJ_TPFRETE

	nFrete:= Val(StrTran(StrTran(HttpPost->CJ_FRETE,'.',''),',','.'))
	cTpOrc:= HttpPost->CJ_XTPORC
	cBandeira:= Iif(Type("HttpPost->CJ_XBAND") <> "U",HttpPost->CJ_XBAND,"")
	nParcela:= Iif(Type("HttpPost->CJ_XPARC") <> "U",val(HttpPost->CJ_XPARC),0)
	cModalidade:= HttpPost->CJ_XMODALI
	nPeso:= Val(StrTran(HttpPost->CJ_XPESO,",","."))
	nVolume:= Val(StrTran(HttpPost->CJ_XVOLUME,",","."))
	cEspecie:= Upper(HttpPost->CJ_XESPECI)
	cNumSCJ := HttpPost->CJ_NUM
	cItens:= HttpPost->aItens
	nOpc:= Val(HttpPost->OPCAO)

//Adiciona observação quando o orçamento é gerado pelo supervisor
	If !Empty(HttpSession->Superv) .and. HttpSession->Superv <> HttpSession->CodVend
		cMsgIn:= " ORÇAMENTO GERADO PELO SUPERVISOR "+Alltrim(HttpSession->Superv)+"."
	Endif



	For x:= 1 to nTotSck
		nPosLin:= At("||",cItens)-1
		If nPosLin > 0
			aLinha:= Separa(Substr(cItens,1,nPosLin),";")
			cItens:= Substr(cItens,nPosLin+3)
			If Len(aLinha) > 0
				aAdd(aItens,aLinha)
			Endif
		Endif
		aLinha:= {}
	Next

//Posiciona nas tabelas
	If !Empty(cCondPag)
		Posicione("SE4",1,xFilial("SE4")+cCondPag,"E4_COND")
	Endif
	If !Empty(cTabela)
		Posicione("DA0",1,xFilial("DA0")+cTabela,"DA0_CODTAB")
		//lPneu := Iif(DA0->DA0_XPOLIM = '1', .F.,.T.)
	Endif
	If !Empty(cCliente)
		Posicione("SA1",1,xFilial("SA1")+Alltrim(HttpPost->CJ_CLIENTE),"A1_COD")
	Endif
	If !Empty(cTransp)
		Posicione("SA4",1,xFilial("SA1")+Alltrim(HttpPost->CJ_XTRANSP),"A4_COD")
	Endif
//Monta o cabeçalho
	If !Empty(cNumSCJ) .and. nOpc = 4// Verificar se deve enviar e-mail -> se mudou o tipo de orcamento de em elaboracao para previsto ou firme
		SCJ->(dbSetOrder(1))	// CJ_FILIAL+CJ_NUM
		if SCJ->(dbSeek(xFilial("SCJ")+cNumSCJ))
			lEnvEmail := (cTpOrc = '1')
		endif
		cFilAnt := xFilial("SCJ")
		// aadd(aCabSCJ,{"CJ_FILIAL",xFilial("SCJ"),Nil})
		aadd(aCabSCJ,{"CJ_NUM",cNumSCJ,Nil})
	Else
		aadd(aCabSCJ,{"CJ_COTCLI",Time(),Nil})
		if !empty(HttpPost->CJ_VEND)
			If !empty(HttpSession->Superv) .and. !empty(HttpSession->Tipo) .and. HttpSession->Tipo = 'S' .and. HttpPost->CJ_VEND = HttpSession->Superv //Se supervisor, atualiza p/o vendedor do cliente
				cSaveVend := SA1->A1_VEND
			else
				cSaveVend := HttpPost->CJ_VEND
			Endif
		else
//			cSaveVend := HttpSession->CodVend
			cSaveVend := cVendLogin
		endif
		//if !empty(SA1->A1_VEND+SA1->A1_VEND2+SA1->A1_VEND3) .and. ! (trim(cSaveVend)+"/" $ trim(SA1->A1_VEND)+"/"+trim(SA1->A1_VEND2)+"/"+trim(SA1->A1_VEND3)+"/")
		if !empty(SA1->A1_VEND) .and. ! (trim(cSaveVend)+"/" $ trim(SA1->A1_VEND)+"/")
			cSaveVend := SA1->A1_VEND
		endif
		aadd(aCabSCJ,{"CJ_VEND", cSaveVend, Nil})

	EndIf
	aadd(aCabSCJ,{"CJ_CLIENTE",SA1->A1_COD,Nil})
	aadd(aCabSCJ,{"CJ_LOJA", SA1->A1_LOJA ,Nil})
	aadd(aCabSCJ,{"CJ_LOJAENT",SA1->A1_LOJA ,Nil})
	aadd(aCabSCJ,{"CJ_CONDPAG",cCondPag ,Nil})
	aadd(aCabSCJ,{"CJ_TABELA" ,cTabela,Nil})
	If !Empty(nDesc1)
		aadd(aCabSCJ,{"CJ_DESC1",nDesc1 ,Nil})
	Endif
	//aadd(aCabSCJ,{"CJ_XNOTAIN",AllTrim(decodeutf8(HttpPost->CJ_XNOTAIN))+cMsgIn,Nil})
	aadd(aCabSCJ,{"CJ_XMSGNF",AllTrim(decodeutf8(HttpPost->CJ_XMSGNF)),Nil})
	aadd(aCabSCJ,{"CJ_TPFRETE" ,cTipoFrete,Nil})
	aadd(aCabSCJ,{"CJ_FRETE" ,nFrete,Nil})
	aadd(aCabSCJ,{"CJ_VALIDA" ,dValidade,Nil})
	aadd(aCabSCJ,{"CJ_XTPORC" ,cTpOrc,Nil})
	aadd(aCabSCJ,{"CJ_XMODALI" ,cModalidade,Nil})
	If !Empty(cTransp)
		aadd(aCabSCJ,{"CJ_XTRANSP",IIf(cTipoFrete $ "SR","",cTransp),Nil})
	Endif
	If !Empty(nParcela)
		aadd(aCabSCJ,{"CJ_XBAND",cBandeira,Nil})
		aadd(aCabSCJ,{"CJ_XPARC",nParcela,Nil})
	Endif
	If !Empty(nPeso)
		aadd(aCabSCJ,{"CJ_XPESO",nPeso ,Nil})
	Endif
	If !Empty(nVolume)
		aadd(aCabSCJ,{"CJ_XVOLUME",nVolume ,Nil})
	Endif
	If !Empty(cEspecie)
		aadd(aCabSCJ,{"CJ_XESPECI",cEspecie ,Nil})
	Endif
	If !Empty(cSerieNF)
		aadd(aCabSCJ,{"CJ_XSERIEN",cSerieNF ,Nil})
	Endif
//Monta os itens
	dbSelectArea("SB1")
	SB1->(dbSetorder(1))


	If ValType(aItens) == "A"  .and. Len(aItens) > 0

		For i:=1 to Len(aItens)
			If ValType(aItens[i,1]) == 'C'
				aLinhaSCJ:={}
				cItem:= StrZero(i,TamSX3("CK_ITEM")[1])
				cProdSck:= PadR(aItens[i,1], TamSX3("CK_PRODUTO")[1])
				nQuantSck :=  val(StrTran(StrTran(aItens[i,2],".",""),",","."))//val(aItens[i,2])
				nPrcVen := aItens[i,3]
				nPrcVen := val(StrTran(StrTran(nPrcVen,".",""),",","."))
				cLocal:= aItens[i,4]
				nValIPI:= aItens[i,5]
				nValIPI := val(StrTran(StrTran(nValIPI,".",""),",","."))
				nValICMS:= aItens[i,6]
				nValICMS := val(StrTran(StrTran(nValICMS,".",""),",","."))
				nValST:= aItens[i,7]
				nValST := val(StrTran(StrTran(nValST,".",""),",","."))
				cTes := aItens[i,8]
				nPerCom:= aItens[i,9]
				nPerCom:= val(StrTran(StrTran(nPerCom,".",""),",","."))
				nAliICMS:= aItens[i,10]
				nAliICMS:= val(StrTran(StrTran(nAliICMS,".",""),",","."))
				nAliIPI:= aItens[i,11]
				nAliIPI:= val(StrTran(StrTran(nAliIPI,".",""),",","."))
				nAliST:= aItens[i,12]
				nAliST:= val(StrTran(StrTran(nAliST,".",""),",","."))
				nDescont:= Iif(Empty(aItens[i,13]),0,Val(StrTran(aItens[i,13],",",".")))
				cPedCli:= aItens[i,14]
				cItemCli:= aItens[i,15]
				nPrcImp := aItens[i,16]
				nPrcImp := val(StrTran(StrTran(nPrcImp,".",""),",","."))

				If SB1->(dbSeek(xFilial("SB1")+cProdSck)) .and. nQuantSck > 0 .And. nPrcVen > 0	.and. SB1->B1_MSBLQL <> '1'
					aadd(aLinhaScj,{"CK_ITEM"	,cItem,Nil})
					aadd(aLinhaScj,{"CK_PRODUTO",SB1->B1_COD,Nil})
					aadd(aLinhaScj,{"CK_LOCAL"	,cLocal,Nil})
					aadd(aLinhaScj,{"CK_QTDVEN" ,nQuantSck,Nil})
					aadd(aLinhaScj,{"CK_TES" 	,cTes,Nil})
					//Não aplica o desconto para produtos de promoção
					If Posicione("DA1",1,xFilial("DA1")+cTabela+SB1->B1_COD,"DA1_TIPPRE") = "5"
						nPrcVen1:= nPrcVen
					Else
						nPrcVen1:= nPrcVen-(nPrcVen*(nDesc1/100))
					Endif
					aadd(aLinhaScj,{"CK_PRUNIT" ,A410Arred(nPrcVen, "CK_PRUNIT"),Nil})
					aadd(aLinhaScj,{"CK_PRCVEN" ,A410Arred(nPrcVen1, "CK_PRCVEN"),Nil})
					aadd(aLinhaScj,{"CK_VALOR" ,A410Arred(nQuantSck*A410Arred(nPrcVen1, "CK_PRCVEN"),"CK_VALOR"),Nil})

					//aadd(aLinhaScj,{"CK_DESCONT",nDescont,Nil})

					//aadd(aLinhaScj,{"CK_ENTREG" ,dDtEntreg,Nil})
					aadd(aLinhaScj,{"CK_XVALIPI",nValIPI,Nil})
					aadd(aLinhaScj,{"CK_XVALICM",nValICMS,Nil})
					aadd(aLinhaScj,{"CK_XICMST"	,nValST,Nil})
					aadd(aLinhaScj,{"CK_XALIICM",nAliICMS,Nil})
					aadd(aLinhaScj,{"CK_XALIIPI",nAliIPI,Nil})
					aadd(aLinhaScj,{"CK_XALIST ",nAliST,Nil})
					aadd(aLinhaScj,{"CK_XPEDCLI",cPedCli,Nil})
					aadd(aLinhaScj,{"CK_XITEMCL",cItemCli,Nil})
					//aadd(aLinhaScj,{"CK_XPRCIMP",nPrcImp,Nil})
					//aadd(aLinhaScj,{"CK_XDESC"	,nDescont,Nil})
					aadd(aLinhaScj,{"CK_XCODBAR",aItens[i,17],Nil})
					aadd(aItemScj,aLinhaScj)
				Else
					lRet:= .F.
				Endif
			Endif
		Next

		//Chama execauto para inclusão do orçamento
		If Len(aCabSCJ) > 0 .and. Len(aItemSCJ) > 0 .and. lRet
			lMsErroAuto:= .F.
			MATA415(aCabSCJ,aItemSCJ,nOpc)
		Else
			If !Empty(cNumSCJ)
				conout(Procname()+"("+ltrim(str(procline()))+") *** Portal "+"FALHA AO INCLUIR O ORÇAMENTO. REFAÇA A OPERAÇÃO!")
			Else
				conout(Procname()+"("+ltrim(str(procline()))+") *** Portal "+"FALHA AO ALTERAR O ORÇAMENTO. REFAÇA A OPERAÇÃO!")
			EndIf
			lRet := .F.
		Endif

		If lMsErroAuto
			If !ExistDir(cDirErro)
				MakeDir(cDirErro)
			Endif

			cDirErro+=dtos(date())
			If !ExistDir(cDirErro)
				MakeDir(cDirErro)
			Endif
			//Grava o erro
			cMsg:= MostraErro(cDirErro,"erro_orcto_"+strtran(time(),":","")+"_"+cFilAnt+".txt")
			cDestMail:= GetNewPar("PR_DESTORE ","lucilene@smsti.com.br")
			u_MailCM("ERRO ORCAMENTO",{cDestMail},{},"ERRO ORCAMENTO NO PORTAL",cMsg,"","")
			cHtml:= "erro"
		Else

			cHtml:= SCJ->CJ_NUM+"<br><br>"

			cDestOrc := GetNewPar("PR_DESTORC","")

			//Envia e-mail informando a inclusão do orçamento
			If !Empty(cDestOrc) .and. (nOpc = 3 .or. lEnvEmail) .and. SCJ->CJ_XTPORC = '1' //não envia para orçamento previsto
				cMsg:= "Um novo orçamento foi gerado pelo Portal do Representante.<br><br>"
				cMsg+= "Filial: "+SCJ->CJ_FILIAL+"<br>"
				cMsg+= "Número: "+SCJ->CJ_NUM+"<br> "
				cMsg+= "Vendedor: "+SCJ->CJ_VEND+" - "+Alltrim(Posicione("SA3",1,xFilial("SA3")+SCJ->CJ_VEND,"A3_NOME"))+"<br>"
				cMsg+= "Cliente: "+SCJ->CJ_CLIENTE+"/"+SCJ->CJ_LOJA+" - "+Posicione("SA1",1,+xFilial("SA1")+SCJ->CJ_CLIENTE+SCJ->CJ_LOJA,"A1_NOME")+"<br>"
				//cMsg+= "Observação Interna: "+SCJ->CJ_XNOTAIN+"<br><br>"
				//cMsg+= "Acesse o Protheus para efetivar o orçamento."
				u_MailCM("ORÇAMENTO",{cDestOrc},{},"NOVO ORCAMENTO PORTAL: "+SCJ->CJ_FILIAL+"/"+SCJ->CJ_NUM+" - "+;
					trim(Posicione("SA1",1,+xFilial("SA1")+SCJ->CJ_CLIENTE+SCJ->CJ_LOJA,"A1_NOME")),cMsg,"","")
			Endif
		EndIf
	Else
		cHtml:= "erro"
	Endif

	Web Extended End

Return (cHTML)

/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ GetLikePro 	¦ Autor ¦ Lucilene Mendes   ¦ Data ¦ 02.09.17 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Busca os produtos de acordo com chave de busca			  ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/
User Function GetLikePro()
	Local cHtml
	Local cTabela:= HttpPost->TABELA
	Local cProds := ""
	Local cGrupo := ""
	Local cDescDig	:= HttpPost->DIGIT

	Web Extended Init cHtml Start U_inSite()

	// TODO - Pedro 20210208 - Remover???
	If Empty(HttpSession->CodVend)
		cHtml:= '<META HTTP-EQUIV="Refresh" CONTENT="0 ; URL=U_PortalLogin.apw">'
		Return cHtml
	endif

	//Atualiza a variável de sessão
	HttpSession->TABELA := cTabela
	cDescDig:= FwNoAccent(Upper(cDescDig))

	conout("******************* tabela -->>  "+cTabela)
	conout("******************* prod busca -->>  "+cDescDig)

	cQry:="Select DA1_CODTAB, B1_GRUPO, BM_DESC, DA1_CODPRO, B1_DESC "
	cQry+=" From "+RetSqlName("DA1")+" DA1"
	cQry+=" INNER JOIN "+RetSqlName("DA0")+" DA0 ON DA0_FILIAL = DA1_FILIAL AND DA0_CODTAB = DA1_CODTAB AND DA0_ATIVO = '1' AND DA0.D_E_L_E_T_ = ' ' "
	cQry+=" INNER JOIN "+RetSqlName("SB1")+" SB1 ON B1_FILIAL = '"+xFilial("SB1")+"' AND B1_COD = DA1_CODPRO AND B1_MSBLQL <> '1' AND SB1.D_E_L_E_T_ = ' ' "
	cQry+=" INNER JOIN "+RetSqlName("SBM")+" SBM ON BM_FILIAL = '"+xFilial("SBM")+"' AND B1_GRUPO = BM_GRUPO AND SBM.D_E_L_E_T_ = ' ' "
	cQry+=" Where DA1_FILIAL = '"+xFilial("DA1")+"' "
	cQry+=" And DA1_CODTAB = '"+cTabela+"' "
	cQry+=" AND DA1_ATIVO = '1' "
	cQry+=" AND DA1_PRCVEN > 0 "
	CQry+=" AND (B1_DESC LIKE '%"+cDescDig+"%' OR B1_COD LIKE '%"+cDescDig+"%') "
	cQry+=" AND DA1.D_E_L_E_T_ = ' ' "
	cQry+=" Order by DA1_CODTAB, B1_GRUPO, B1_COD "

    conout("Query Produtos -->"+cQry)
/*
	If Select("QRP") > 0
		QRP->(dbCloseArea())
	Endif
	APWExOpenQuery(ChangeQuery(cQry),'QRP',.T.)

	//Preenche o select de produtos
	While QRP->(!Eof())
		If Empty(cGrupo)
			cProds+= '<optgroup label="'+Alltrim(Strtran(QRP->BM_DESC,"'",""))+'">
		Elseif !Empty(cGrupo) .and. cGrupo <> QRP->B1_GRUPO
			cProds+= '</optgroup>'
			cProds+= '<optgroup label="'+Alltrim(Strtran(QRP->BM_DESC,"'",""))+'">
		Endif
		cProds+='	<option value="'+Alltrim(QRP->DA1_CODPRO)+'">'+Alltrim(QRP->DA1_CODPRO)+' - '+Alltrim(u_RemEspec(QRP->B1_DESC))+'</option>'
		cGrupo:= QRP->B1_GRUPO
		QRP->(dbSkip())
	End
	If !Empty(cProds)
		cProds+= '</optgroup>'
	Endif
	cHtml:= cProds


*/

	If Select("QRP") > 0
		QRP->(dbCloseArea())
	Endif
	APWExOpenQuery(ChangeQuery(cQry),'QRP',.T.)

	//Preenche o select de produtos
	While QRP->(!Eof())
		if ! (cGrupo == QRP->B1_GRUPO)
			If !Empty(cGrupo)
				cProds+= '</optgroup>'
			Endif
			cProds+= '<optgroup label="'+EncodeUTF8(Alltrim(Strtran(QRP->BM_DESC,"'","")))+'">
		Endif
		cProds+='	<option value="'+Alltrim(QRP->DA1_CODPRO)+'">'+Alltrim(QRP->DA1_CODPRO)+' - '+encodeUTF8(Alltrim(Strtran(QRP->B1_DESC,"'","")))+'</option>'
		cGrupo:= QRP->B1_GRUPO
		QRP->(dbSkip())
	End
	If !Empty(cProds)
		cProds+= '</optgroup>'
	Endif

	cHtml:= cProds


	Web Extended end

Return cHtml

//Função chamada pela listCliente
User Function GetLikeCli()

	Local cHtml
	Local cCliente:= Upper(HttpPost->DESCCLI)
	Local cCli := ""

	Web Extended Init cHtml Start U_inSite()

	cVendLogin := u_GetUsrPR()
	cCodLogin  := U_SetParPR(cVendLogin)
	cCodVend:=cVendLogin

	// TODO - Pedro 20210208 - Remover???
	If Empty(HttpSession->CodVend)
		cHtml:= '<META HTTP-EQUIV="Refresh" CONTENT="0 ; URL=U_PortalLogin.apw">'
		Return cHtml
	endif

	cQuery := " Select A1_COD, A1_LOJA, A1_CGC, A1_NOME, A1_BAIRRO, A1_END, A1_MUN, A1_EST, A1_DDD, A1_TEL, A1_COND "
	cQuery += " From "+RetSqlName("SA1")+" SA1 "
	cQuery += " Where A1_FILIAL = '"+xFilial("SA1")+"' "
	If HttpSession->Tipo = 'S' //Supervisor acessa todos os clientes da sua equipe
		cQuery += " AND A1_REGIAO = '"+HttpSession->Regional+"' " 
	Else
		If SA3->A3_TIPO <> "I" //vendedor interno deve exibir todos os clientes
			cQuery+= " AND A1_VEND = '"+cCodVend+"'" // OR A1_VEND2 = '"+cCodVend+"'  OR A1_VEND3= '"+cCodVend+"' OR A1_VEND4= '"+cCodVend+"' OR A1_VEND5 = '"+cCodVend+"' ) "
		Endif
	Endif
	cQuery += " And A1_MSBLQL <> '1' "
	cQuery += " AND (A1_CGC LIKE '%"+cCliente+"%' OR A1_NOME LIKE '%"+cCliente+"%') "
	cQuery += " And SA1.D_E_L_E_T_ = ' ' "
	cQuery += " Order by A1_NOME "

    conout("Query Clientes -->"+cQuery)

	If Select("QRCLI") > 0
		QRCLI->(dbCloseArea())
	Endif
	APWExOpenQuery(ChangeQuery(cQuery),'QRCLI',.T.)

	dbSelectArea("QRCLI")
	//Preenche o select de produtos
	While QRCLI->(!Eof())

		cCli+='	<option value="'+Alltrim(QRCLI->A1_COD+QRCLI->A1_LOJA)+'">'+QRCLI->A1_COD+'/';
		+QRCLI->A1_LOJA+' - '+Alltrim(QRCLI->A1_NOME)+' - '+QRCLI->A1_CGC+' - '+trim(QRCLI->A1_MUN) +'</option>'
		QRCLI->(dbSkip())
	End
	APWExCloseQuery('QRCLI')

	cHtml:= cCli


	Web Extended end

Return cHtml

/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ GetPerFrt 	¦ Autor ¦ Lucilene Mendes   ¦ Data ¦ 02.09.17 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Busca o percentual de frete da cidade/estado da SZ3		  ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/
User Function GetPerFrt()
	Local cHtml
	Local cQry:= ""
	Local cUF:= HttpPost->UF
	Local cCodMun:= HttpPost->MUN

	Web Extended Init cHtml Start U_inSite()

	If Empty(HttpSession->CodVend)
		cHtml:= '<META HTTP-EQUIV="Refresh" CONTENT="0 ; URL=U_PortalLogin.apw">'
		Return cHtml
	endif

	//Busca os itens da tabela de preço
	cQry:="Select Z3_PERFRAD "
	cQry+=" From "+RetSqlName("SZ3")+" SZ3"
	cQry+=" Where SZ3_FILIAL = '"+xFilial("SZ3")+"' "
	cQry+=" And Z3_UF = '"+cUF+"' "
	cQry+=" AND AND (Z3_MUNICIP = '"+cCodMun+"' OR Z3_MUNICIP= ' ' ) "
	cQry+=" AND SZ3.D_E_L_E_T_ = ' ' "
	cQry+=" Order by Z3_MUNICIP DESC "

	If Select("QRP") > 0
		QRP->(dbCloseArea())
	Endif
	APWExOpenQuery(ChangeQuery(cQry),'QRP',.T.)

	//Verifica se existe registro
	If QRP->(!Eof())
		cHtml:= cvaltochar(QRP->Z3_PERFRAD)
	Else
		cHtml:= "0"
	End
	Web Extended end

Return cHtml

/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ GetDadosOpt 	¦ Autor ¦ Lucilene Mendes   ¦ Data ¦ 02.09.17 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Busca o vendedor da oportunidade							  ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/
User Function GetDadosOpt()
	Local cHtml
	Local cOport:= HttpPost->Oportunidade

	Web Extended Init cHtml Start U_inSite()

	If Empty(HttpSession->CodVend)
		cHtml:= '<META HTTP-EQUIV="Refresh" CONTENT="0 ; URL=U_PortalLogin.apw">'
		Return cHtml
	endif

	If AD1->(dbSeek(xFilial("AD1")+cOport))
		cHtml:= "OK|#|"+cvaltochar(AD1->AD1_COMIRT)+"|#|"
		cHtml+= u_ListaVend(.F.,Alltrim(AD1->AD1_VEND))+"|#|"
		cHtml+= Alltrim(AD1->AD1_VEND)
	Else
		cHtml:= ""
	End
	Web Extended end

Return cHtml

/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ GetProdutos 	¦ Autor ¦ Lucilene Mendes   ¦ Data ¦ 02.09.17 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Função utilizada no Ajax pra retornar os produtos da tabela¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/
User Function GetProdutos()
	Local cHtml
	Local cCliente:= HttpPost->CLIENTE
	Local cTabela:= HttpPost->TABELA
	Local cProds := ""
	Local cGrupo := ""

	Web Extended Init cHtml Start U_inSite()

	If Empty(HttpSession->CodVend)
		cHtml:= '<META HTTP-EQUIV="Refresh" CONTENT="0 ; URL=U_PortalLogin.apw">'
		Return cHtml
	endif
	//Atualiza a variável de sessão
	HttpSession->TABELA := cTabela

	//Busca os itens da tabela de preço
	cQry:="Select DA1_CODTAB, B1_GRUPO, BM_DESC, DA1_CODPRO, B1_XDESGIR B1_DESC, B1_PROC "
	cQry+=" From "+RetSqlName("DA1")+" DA1"
	cQry+=" INNER JOIN "+RetSqlName("DA0")+" DA0 ON DA0_FILIAL = DA1_FILIAL AND DA0_CODTAB = DA1_CODTAB AND DA0_ATIVO = '1' AND DA0.D_E_L_E_T_ = ' ' "
	cQry+=" INNER JOIN "+RetSqlName("SB1")+" SB1 ON B1_FILIAL = '"+xFilial("SB1")+"' AND B1_COD = DA1_CODPRO AND B1_MSBLQL <> '1' AND SB1.D_E_L_E_T_ = ' ' "
	cQry+=" LEFT JOIN "+RetSqlName("SBM")+" SBM ON BM_FILIAL = '"+xFilial("SBM")+"' AND B1_GRUPO = BM_GRUPO AND SBM.D_E_L_E_T_ = ' ' "
	cQry+=" Where DA1_FILIAL = '"+xFilial("DA1")+"' "
	cQry+=" And DA1_CODTAB = '"+cTabela+"' "
	cQry+=" AND DA1_ATIVO = '1' "
	cQry+=" AND DA1_PRCVEN > 0 "
	cQry+=" AND DA1.D_E_L_E_T_ = ' ' "
	cQry+=" Order by DA1_CODTAB, B1_GRUPO, B1_COD "

	If Select("QRP") > 0
		QRP->(dbCloseArea())
	Endif
	APWExOpenQuery(ChangeQuery(cQry),'QRP',.T.)

	//Preenche o select de produtos
	While QRP->(!Eof())
		If Empty(cGrupo)
			cProds+= '<optgroup label="'+Alltrim(Strtran(QRP->BM_DESC,"'",""))+'">
		Elseif !Empty(cGrupo) .and. cGrupo <> QRP->B1_GRUPO
			cProds+= '</optgroup>'
			cProds+= '<optgroup label="'+Alltrim(Strtran(QRP->BM_DESC,"'",""))+'">
		Endif
		cProds+='	<option value="'+Alltrim(QRP->DA1_CODPRO)+'">'+Alltrim(QRP->DA1_CODPRO)+' - '+Alltrim(Strtran(QRP->B1_DESC,"'",""))+' - '+Alltrim(QRP->B1_PROC)+'</option>'
		cGrupo:= QRP->B1_GRUPO
		QRP->(dbSkip())
	End
	If !Empty(cProds)
		cProds+= '</optgroup>'
	Endif
	cHtml:= cProds


	Web Extended end

Return cHtml

/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ GatProd   	¦ Autor ¦ Lucilene Mendes   ¦ Data ¦ 05.09.17 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Gatilho para atualização dos preços ao selecionar o produto¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/
User Function GatProd()
	Local cProduto	:= Alltrim(UnEscape(HttpPost->PRODUTO))
	Local nQuant	:= Iif(Type("HttpPost->quant")<>"U",val(HttpPost->quant),0)
	Local cTabela	:= Alltrim(HttpSession->Tabela)
	Local cCliente	:= Alltrim(HttpSession->Cliente)
	Local cSepField := "|#|"
	Local cTes		:= ""
	Local cTpPreco	:= ""
	Local nQtdFis 	:= 1
	Local nDesc		:= 0
	Local nValIcms	:= 0
	Local nBaseIcms	:= 0
	Local nValST	:= 0
	Local nBaseST	:= 0
	Local nValIPI	:= 0
	Local nBaseIPI	:= 0
	Local cAliqIPI	:= 0
	Local cAliqICMS	:= 0
	Local cAliqST	:= 0
	Local nQtdMin	:= 0
	Local aRet		:= {}
	Local cHtml

	nSec:= Seconds()

	Web Extended Init cHtml Start U_inSite()

	Conout("[ADDORC / GATPROD] - tempo Abertura InSite: "+cValtoChar(Seconds()-nSec)+"s")

	//Busca o cadastro do cliente
	Posicione("SA1",1,xFilial("SA1")+cCliente,"A1_COD")

	//Posiciona no cadastro do produto
	Posicione("SB1",1,xFilial("SB1")+cProduto,"B1_COD")

	//Posiciona na tabela de preço
	Posicione("DA0",1,xFilial("DA0")+cTabela,"DA0_CODTAB")

	//Verifica o valor pela quantidade mínima
	If nQuant > 0
		cQry:="Select DA1.R_E_C_N_O_ RECDA1 "
		cQry+=" From "+RetSqlName("DA1")+" DA1 "
		cQry+=" Where DA1_FILIAL = '"+xFilial("DA1")+"' "
		cQry+=" AND DA1_CODTAB = '"+cTabela+"' "
		cQry+=" AND DA1_CODPRO = '"+cProduto+"' "
		//cQry+=" AND DA1_XQTMIN <= "+cvaltochar(nQuant)+" "
		cQry+=" AND DA1.D_E_L_E_T_ = ' ' "
		//cQry+=" ORDER BY DA1_XQTMIN DESC "
		If Select("QDA1") > 0
			QDA1->(dbCloseArea())
		Endif
		TcQuery cQry New Alias "QDA1"

		DA1->(dbGoto(QDA1->RECDA1))
		nPrcTab := DA1->DA1_PRCVEN
		//nQtdMin:= DA1->DA1_XQTMIN
		cTpPreco:= DA1->DA1_TIPPRE
		QDA1->(dbCloseArea())
	Else
		Posicione("DA1",1,xFilial("DA1")+cTabela+cProduto,"DA1_CODTAB")
		nPrcTab := DA1->DA1_PRCVEN
		//nQtdMin:= DA1->DA1_XQTMIN
		cTpPreco:= DA1->DA1_TIPPRE
	Endif


	If nPrcTab > 0

		nSec:= Seconds()
		//Obtem os valores de impostos
		u_GetValImp(SA1->A1_COD+SA1->A1_LOJA,nPrcTab,nDesc,nQtdFis,@nValIcms,@nBaseICMS,@nValST,@nBaseST,@nValIPI,@nBaseIPI,@cAliqIPI,@cAliqICMS,@cAliqST,@cTes)

		Conout("[ADDORC / GATPROD] - tempo u_GetValImp: "+cValtoChar(Seconds()-nSec)+"s")

		If Empty(cTes)
			cHtml:= "ERRO: TES nao localizada."
		Else

			cPrcTab := TransForm((nPrcTab),PesqPict("SCK","CK_PRCVEN"))
			cTotalST:= Transform(((nPrcTab)+nValST),PesqPict("SCK","CK_PRCVEN"))

			aAdd(aRet,Alltrim(SB1->B1_UM))
			aAdd(aRet,Alltrim(cPrcTab))
			aAdd(aRet,Alltrim(Transform(nValIcms,PesqPict("SCK","CK_XVALICM"))))
			aAdd(aRet,Alltrim(Transform(nValIPI,PesqPict("SCK","CK_XVALIPI"))))
			aAdd(aRet,Alltrim(Transform(nValST,PesqPict("SCK","CK_PRCVEN"))))
			aAdd(aRet,cAliqIPI)
			aAdd(aRet,cAliqICMS)
			aAdd(aRet,cValtochar(SB1->B1_QE))
			aAdd(aRet,cTES)
			aAdd(aRet,cValtoChar(nBaseICMS))
			aAdd(aRet,cValtoChar(nBaseST))
			aAdd(aRet,cValtoChar(nBaseIPI))
			aAdd(aRet,cAliqST)
			aAdd(aRet,SB1->B1_GRUPO)
			aAdd(aRet,cvaltochar(nQtdMin))
			aAdd(aRet,SB1->B1_LOCPAD) //15
			aAdd(aRet,u_GetEstDisp())
			
			cHtml := "OK:"
			cHtml += aRet[1]+cSepField+aRet[2]+cSepField+aRet[3]+cSepField+aRet[4]+cSepField+aRet[5]+cSepField+aRet[6]+cSepField+aRet[7]+cSepField+aRet[8]
			cHtml +=cSepField+aRet[9]+cSepField+aRet[10]+cSepField+aRet[11]+cSepField+aRet[12]+cSepField+aRet[13]+cSepField+aRet[14]+cSepField+aRet[15]
			cHtml +=cSepField+aRet[16]+cSepField+aRet[17]+cSepField+aRet[18]+cSepField+aRet[19]+cSepField+aRet[20]
		Endif
	Else
		cHtml := "ERRO: Nao foi possivel localizar o produto"
	Endif

	Web Extended end
CONOUT("FIM GATPROD")
Return cHtml

User Function GetImpostos()
	Local cProduto	:= Alltrim(UnEscape(HttpPost->PRODUTO))
	Local nPrcTab	:= Val(HttpPost->prcvenda)
//	Local cTabela	:= Alltrim(HttpSession->Tabela)
	Local cCliente	:= Alltrim(HttpSession->Cliente)
	Local nQtdFis 	:= Val(HttpPost->quantidade)
//	Local cSepReg 	:= "#*#*"
	Local cSepField := "|#|"
	Local cTes		:= ""
	Local nDesc 	:= 0
	Local nValIcms	:= 0
	Local nBaseIcms	:= 0
	Local nValST	:= 0
	Local nBaseST	:= 0
	Local nValIPI	:= 0
	Local nBaseIPI	:= 0
	Local cAliqIPI	:= 0
	Local cAliqICMS	:= 0
	Local cAliqST	:= 0
	Local aRet		:= {}
	Local cHtml

	Web Extended Init cHtml Start U_inSite()

	//Busca o cadastro do cliente
	Posicione("SA1",1,xFilial("SA1")+cCliente,"A1_COD")

	//Posiciona no cadastro do produto
	Posicione("SB1",1,xFilial("SB1")+cProduto,"B1_COD")

	If nPrcTab > 0

		//Obtem os valores de impostos
		u_GetValImp(SA1->A1_COD+SA1->A1_LOJA,nPrcTab,nDesc,nQtdFis,@nValIcms,@nBaseICMS,@nValST,@nBaseST,@nValIPI,@nBaseIPI,@cAliqIPI,@cAliqICMS,@cAliqST,@cTes)

		nValDesc:= nPrcTab * nDesc
		cPrcTab := TransForm((nPrcTab-nValDesc),PesqPict("SCK","CK_PRCVEN"))
//		cPrcTab := TransForm((nPrcTab-nValDesc),PesqPict("SCK","CK_PRCVEN"))
		cTotalST:= Transform(((nPrcTab-nValDesc)+nValST),PesqPict("SCK","CK_PRCVEN"))

		aAdd(aRet,Alltrim(SB1->B1_UM))
		aAdd(aRet,Alltrim(cPrcTab))
		aAdd(aRet,Alltrim(Transform(nValIcms,PesqPict("SCK","CK_XVALICM"))))
		aAdd(aRet,Alltrim(Transform(nValIPI,PesqPict("SCK","CK_XVALIPI"))))
		aAdd(aRet,Alltrim(cValtoChar(nValST)))
		//aAdd(aRet,Alltrim(Transform(nValST,PesqPict("SCK","CK_PRCVEN"))))
		aAdd(aRet,cAliqIPI)
		aAdd(aRet,cAliqICMS)
		aAdd(aRet,cValtochar(SB1->B1_QXQEMB))
		aAdd(aRet,cTES)
		aAdd(aRet,cValtoChar(nBaseICMS))
		aAdd(aRet,cValtoChar(nBaseST))
		aAdd(aRet,cValtoChar(nBaseIPI))
		aAdd(aRet,cAliqST)

		cHtml := "OK:"
		cHtml += aRet[1]+cSepField+aRet[2]+cSepField+aRet[3]+cSepField+aRet[4]+cSepField+aRet[5]+cSepField+aRet[6]+cSepField+aRet[7]+cSepField+aRet[8]
		cHtml +=cSepField+aRet[9]+cSepField+aRet[10]+cSepField+aRet[11]+cSepField+aRet[12]+cSepField+aRet[13]
	Else
		cHtml := "Falha ao calcular impostos"
	Endif

	Web Extended end

Return cHtml

/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ GetValImp   ¦ Autor ¦ Anderson Zelenski  ¦ Data ¦ 09.09.17 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Função para cálculo dos impostos						      ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/
User Function GetValImp(cCliente,nPreco,nDesc,nQtdFis,nValIcms,nBaseIcms,nValST,nBaseST,nValIPI,nBaseIPI,cAliqIPI,cAliqICMS,cAliqST,cTes)
	Local _nItem:= 0
	Local cCodOper:= ""
	MaFisEnd()

	SA1->(dbSetorder(1))
	SA1->(dbSeek(xFilial("SA1")+cCliente))

	cCodOper:= Iif(Empty(SA1->A1_OPER),GetNewPar("PR_CODOPER","01"),SA1->A1_OPER)

	MaFisIni(SA1->A1_COD,;// 1-Codigo Cliente/Fornecedor
	SA1->A1_LOJA,;// 2-Loja do Cliente/Fornecedor
	"C",; // 3-C:Cliente , F:Fornecedor
	"N",; // 4-Tipo da NF
	SA1->A1_TIPO,;// 5-Tipo do Cliente/Fornecedor
	MaFisRelImp("MT100", {"SF2", "SD2"}),; // 6-Relacao de Impostos que suportados no arquivo
	,;// 7-Tipo de complemento
	,;// 8-Permite Incluir Impostos no Rodape .T./.F.
	"SB1",; // 9-Alias do Cadastro de Produtos - ("SBI" P/ Front Loja)
	"MATA461")

	dbSelectArea("SE4")
	SE4->(DbSetOrder(1))

	cTes:= MaTesInt(2,cCodOper,SA1->A1_COD,SA1->A1_LOJA,"C",SB1->B1_COD,"",SA1->A1_TIPO)
	// conout("tes -->"+cTes)
	// conout("prod -->"+SB1->B1_COD)
	_nItem := MaFisAdd(SB1->B1_COD,; // 1-Codigo do Produto ( Obrigatorio )
	cTes,;// 2-Codigo do TES ( Opcional )
	nQtdFis,; // 3-Quantidade ( Obrigatorio )
	nPreco,; // 4-Preco Unitario ( Obrigatorio )
	nDesc,; // 5-Valor do Desconto ( Opcional )
	,;// 6-Numero da NF Original ( Devolucao/Benef )
	,;// 7-Serie da NF Original ( Devolucao/Benef )
	,;// 8-RecNo da NF Original no arq SD1/SD2
	0,; // 9-Valor do Frete do Item ( Opcional )
	0,; // 10-Valor da Despesa do item ( Opcional )
	0,; // 11-Valor do Seguro do item ( Opcional )
	0,; // 12-Valor do Frete Autonomo ( Opcional )
	nPreco,; // 13-Valor da Mercadoria ( Obrigatorio )
	0,; // 14-Valor da Embalagem ( Opiconal )
	0,; // 15-RecNo do SB1
	0)// 16-RecNo do SF4

//ICMS
	nValIcms:= MaFisRet(_nItem,"IT_VALICM")
	nBaseIcms:= MaFisRet(_nItem,"IT_BASEICM")
	cAliqICMS:= Alltrim(Str(MaFisRet(_nItem,"IT_ALIQICM")))

//IPI
	nValIPI := MaFisRet(_nItem,"IT_VALIPI")
	nBaseIPI := MaFisRet(_nItem,"IT_BASEIPI")
	cAliqIPI := Alltrim(Str(MaFisRet(_nItem,"IT_ALIQIPI")))

//ICMS ST
	nValST	:= MaFisRet(_nItem,"IT_VALSOL")
	nBaseST := MaFisRet(_nItem,"IT_BASESOL")
	cAliqST	:= Alltrim(Str(MaFisRet(_nItem,"IT_ALIQSOL")))

Return


/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ FreteMinimo ¦ Autor ¦ Lucilene Mendes  	¦ Data ¦ 09.09.17 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Validação para valor mínimo do frete.				      ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/
User Function FreteMinimo()
	Local cHtml
	Local cCliente	:= Alltrim(HttpSession->Cliente)
	Local cTipo		:= Alltrim(HttpPost->tipoFrete)
	Local cUF		:= ""
	Local nValMin	:= 0

	Web Extended Init cHtml Start U_inSite()

	If Empty(HttpSession->CodVend)
		cHtml:= '<META HTTP-EQUIV="Refresh" CONTENT="0 ; URL=U_PortalLogin.apw">'
		Return cHtml
	endif

	//Busca o UF do cliente
	cUF:= Posicione("SA1",1,xFilial("SA1")+cCliente,"A1_EST")

	//Busca o valor mínimo
	nValMin:= GetNewPar("PR_FRTMIN",0)

	cHtml:= cvaltochar(nValMin)

	Web Extended end

Return cHtml

/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ VldCondPg ¦ Autor ¦ Lucilene Mendes  	¦ Data ¦ 09.09.17 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Verifica valor mínimo de parcela.					      ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/
User Function VldCondPg()
	Local cHtml
	Local cCondPag	:= Alltrim(HttpPost->condPgto)

	Web Extended Init cHtml Start U_inSite()

	If Empty(HttpSession->CodVend)
		cHtml:= '<META HTTP-EQUIV="Refresh" CONTENT="0 ; URL=U_PortalLogin.apw">'
		Return cHtml
	endif

	//Posiciona na condição
	SE4->(dbSeek(xFilial("SE4")+cCondPag))

	cHtml:= cvaltochar(SE4->E4_DESCRI)

	Web Extended end

Return cHtml

/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ GetSitCli    ¦ Autor ¦ Lucilene Mendes   ¦ Data ¦ 19.11.17 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Função para buscar os dados de crédito do cliente.         ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/
User Function GetSitCli()
	Local cHtml
	Local cCliente	:= Alltrim(HttpPost->Cliente)
	Local cMsg	:= ""
	Local cSepField := "|#|"
	Local lRetCli:= .T.
	Private cMsgCust:= ""

	Web Extended Init cHtml Start U_inSite()

	If Empty(HttpSession->CodVend)
		cHtml:= '<META HTTP-EQUIV="Refresh" CONTENT="0 ; URL=U_PortalLogin.apw">'
		Return cHtml
	endif
	//Posiciona no cliente
	dbSelectArea("SA1")
	SA1->(dbSeek(xFilial("SA1")+cCliente))
	//Atualiza a variável de sessão
	HttpSession->cliente := cCliente

	//Chama a validação customizada do cliente
	If ExistBlock("VldPortalSMS")
	 	lRetCli:=u_VldPortalSMS("CJ_CLIENTE",SA1->(Recno()))
	Endif

	If !Empty(cMsgCust)
		cMsg+= '<div class="row form-group">'+CHR(13)+CHR(10)
		cMsg+= '<div class="col-lg-12">'+CHR(13)+CHR(10)
		cMsg+= '	<div class="col-lg-12">'+cMsgCust+'</div>'+CHR(13)+CHR(10)
		cMsg+= '</div>'+CHR(13)+CHR(10)
		cMsg+= '</div>'+CHR(13)+CHR(10)
	Else
		cMsg:="::"
	Endif

	cHtml:= Iif(!lRetCli,'0','1')+cSepField+cMsg+cSepField
	cHtml+= SA1->A1_TIPO+cSepField+SA1->A1_GRPTRIB+cSepField+Alltrim(SA1->A1_COND)+cSepField
	cHtml+= Alltrim(SA1->A1_EST)+Alltrim(SA1->A1_COD_MUN)+" - "+Alltrim(SA1->A1_MUN)

	Web Extended end

Return cHtml


/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ GetCellTb   ¦ Autor ¦ Lucilene Mendes  	¦ Data ¦ 22.11.17 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Função para geração da linha da tabela de itens		      ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/
User Function GetCellTb()

	Local cHtml
	Local nCol	:= HttpPost->coluna
	Local nLin	:= val(HttpPost->linha)
	Local cItem	:= ""
	Local cCampo:= ""

	Web Extended Init cHtml Start U_inSite()

	cItem:= StrZero(nLin,TamSX3("CK_ITEM")[1])

	cCampo:= "var campo = document.createElement('input'); " // create input element
	cCampo+= " campo.setAttribute('class', 'form-control input-block'); "        // set class attribute
	cCampo+= " campo.name = '"+aItens[nCol,2]+cItem+"'; "
	cCampo+= " campo.id = '"+aItens[nCol,2]+cItem+"'; "
	cCampo+= " campo.align = '"+aItens[nCol][4]+"';"

	cHtml:= cCampo

	Web Extended end

Return cHTML

/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ GetCondPgto 	¦ Autor ¦ Lucilene Mendes   ¦ Data ¦ 01.07.19 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Função utilizada no Ajax pra retornar a cond de pagamento  ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/
User Function GetCondPgto()
	Local cHtml
	Local cCliente	:= Alltrim(HttpSession->Cliente)
	Local cModali	:= Alltrim(HttpPost->modali)
	Local cCondCli	:= ""
	Local cCondPg	:= ""

	Web Extended Init cHtml Start U_inSite()

	If Empty(HttpSession->CodVend)
		cHtml:= '<META HTTP-EQUIV="Refresh" CONTENT="0 ; URL=U_PortalLogin.apw">'
		Return cHtml
	endif

	cCondPg+='	<option value=""></option>'

	//Verifica se a condição cadastrada no cliente é dessa modalidade
	cCondCli:= Posicione("SA1",1,xFilial("SA1")+cCliente,"A1_COND")
	SE4->(dbSeek(xFilial("SE4")+cCondCli))
	If SE4->E4_XMODALI == cModali
		cCondPg+='	<option value="'+Alltrim(SE4->E4_CODIGO)+'">'+Alltrim(SE4->E4_CODIGO)+" - "+Alltrim(SE4->E4_DESCRI)+'</option>'
	Else
		cCondCli:=""
	Endif

	//Seleciona as condições de pagamento disponíveis no combo
	cQry:= " Select E4_CODIGO, E4_DESCRI"
	cQry+= " From "+RetSqlName("SE4")+" SE4 "
	cQry+= " Where E4_FILIAL = '"+xFilial("SE4")+"' "
	cQry+= " And E4_XMODALI = '"+cModali+"' "
	cQry+= " And E4_MSBLQL <> '1' "
	cQry+= " And E4_CODIGO <> '"+cCondCli+"' "
	cQry+= " And SE4.D_E_L_E_T_ = ' ' "

	If Select("QRT") > 0
		QRT->(dbCloseArea())
	Endif
	APWExOpenQuery(ChangeQuery(cQry),'QRT',.T.)

	//Preenche o select da tabela
	While QRT->(!Eof())
		cCondPg+='	<option value="'+Alltrim(QRT->E4_CODIGO)+'">'+Alltrim(QRT->E4_CODIGO)+" - "+Alltrim(QRT->E4_DESCRI)+'</option>'
		QRT->(dbSkip())
	End

	cHtml:= cCondPg

	Web Extended end

Return cHtml



/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ GetEstDisp	¦ Autor ¦ Lucilene Mendes   ¦ Data ¦ 04.07.19 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Função utilizada no Ajax pra retornar o estoque disponível ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/
//Estoque disponível: saldo do produto – empenhos – quantidade pedido de venda – quantidade orçamentos Firmes e não efetivados.
User Function GetEstDisp()
	Local cHtml
	Local cProduto	:= Alltrim(UnEscape(HttpPost->produto))
	Local cArmazem	:= ""
	Local lVldEstoq := .T.

	Web Extended Init cHtml Start U_inSite()

	If Empty(HttpSession->CodVend)
		cHtml:= '<META HTTP-EQUIV="Refresh" CONTENT="0 ; URL=U_PortalLogin.apw">'
		Return cHtml
	endif

	lVldEstoq:= GetNewPar("PR_VLDESTQ",.T.)

	If !lVldEstoq
		Return '9999999'
	Endif

	//Armazéns considerados para busca do estoque
	cArmazem:= GetNewPar("PR_ARMZPR","'01','02','03'") //deve estar no formato '01','02'

	//Busca o saldo do produto
  	cQry:= "With QRY AS( "
	cQry+= "Select SUM(B2_QATU) EST , SUM(CASE WHEN B2_QEMP >= 0 THEN B2_QEMP ELSE 0 END) + SUM(CASE WHEN B2_RESERVA >= 0 THEN B2_RESERVA ELSE 0 END) EMPENHO " //adicionado reserva 07.02.20 - Lucilene // + SUM(CASE WHEN B2_QPEDVEN >= 0 THEN B2_QPEDVEN ELSE 0 END)
	cQry+= "From "+RetSqlName("SB2")+" SB2 "
	cQry+= "Where B2_FILIAL = '"+xFilial("SB2")+"' And B2_COD = '"+cProduto+"' And SB2.D_E_L_E_T_ = ' ' "
	If !Empty(cArmazem)
		cQry+= "AND B2_LOCAL in ("+cArmazem+") "
	Endif
	cQry+= "UNION ALL "
	cQry+= "Select 0 EST , SUM(CK_QTDVEN) EMPENHO "
	cQry+= "From "+RetSqlName("SCJ")+" SCJ, "+RetSqlName("SCK")+" SCK "
	cQry+= "Where CJ_FILIAL =  '"+xFilial("SB2")+"'  AND CJ_XTPORC = '1' AND CJ_STATUS = 'A' AND SCJ.D_E_L_E_T_ = ' ' "
	cQry+= "and CK_FILIAL = CJ_FILIAL AND CK_NUM = CJ_NUM AND CK_PRODUTO = '"+cProduto+"' and SCK.D_E_L_E_T_ = ' ' "
	If !Empty(cArmazem)
		cQry+= "AND CK_LOCAL in ("+cArmazem+") "
	Endif
	cQry+= ")"
	cQry+= "SELECT SUM(EST) -SUM(EMPENHO) SALDO FROM QRY "

	If Select("QRS") > 0
		QRS->(dbCloseArea())
	Endif
	APWExOpenQuery(cQry,'QRS',.T.)
	conout(cQry)
	cHtml:= cValtoChar(QRS->SALDO)

	Web Extended end

Return cHtml

/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ GetEstGeral	¦ Autor ¦ Lucilene Mendes   ¦ Data ¦ 14.10.23 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Retorna estoque disponível para todos os armazéns da filial¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯*/
//Estoque disponível: saldo do produto – empenhos – quantidade pedido de venda – quantidade orçamentos Firmes e não efetivados.
User Function GetEstGeral()
	Local cHtml
	Local cProduto	:= Alltrim(UnEscape(HttpPost->produto))

	Web Extended Init cHtml Start U_inSite()

	If Empty(HttpSession->CodVend)
		cHtml:= '<META HTTP-EQUIV="Refresh" CONTENT="0 ; URL=U_PortalLogin.apw">'
		Return cHtml
	Endif

	//Busca o saldo do produto
  	cQry:= "With QRY AS( "
	cQry+= "Select B2_LOCAL ARMAZEM, SUM(B2_QATU) EST , SUM(CASE WHEN B2_QEMP >= 0 THEN B2_QEMP ELSE 0 END) + SUM(CASE WHEN B2_RESERVA >= 0 THEN B2_RESERVA ELSE 0 END) EMPENHO " //adicionado reserva 07.02.20 - Lucilene // + SUM(CASE WHEN B2_QPEDVEN >= 0 THEN B2_QPEDVEN ELSE 0 END)
	cQry+= "From "+RetSqlName("SB2")+" SB2 "
	cQry+= "Where B2_FILIAL = '"+xFilial("SB2")+"' And B2_COD = '"+cProduto+"' And SB2.D_E_L_E_T_ = ' ' "
	cQry+= "GROUP BY B2_LOCAL "
	cQry+= "UNION ALL "
	cQry+= "Select CK_LOCAL ARMAZEM, 0 EST , SUM(CK_QTDVEN) EMPENHO "
	cQry+= "From "+RetSqlName("SCJ")+" SCJ, "+RetSqlName("SCK")+" SCK "
	cQry+= "Where CJ_FILIAL =  '"+xFilial("SB2")+"'  AND CJ_XTPORC = '1' AND CJ_STATUS = 'A' AND SCJ.D_E_L_E_T_ = ' ' "
	cQry+= "and CK_FILIAL = CJ_FILIAL AND CK_NUM = CJ_NUM AND CK_PRODUTO = '"+cProduto+"' and SCK.D_E_L_E_T_ = ' ' "
	cQry+= "GROUP BY CK_LOCAL "
	cQry+= ")"
	cQry+= "SELECT ARMAZEM, SUM(EST) -SUM(EMPENHO) SALDO FROM QRY "
	cQry+= "GROUP BY ARMAZEM "
	cQry+= "HAVING (SUM(EST) -SUM(EMPENHO)) > 0"

	If Select("QRS") > 0
		QRS->(dbCloseArea())
	Endif
	APWExOpenQuery(cQry,'QRS',.T.)

	cTabela:= '<table class="table table-bordered table-striped table-condensed mb-none" id="saldoEstGeral">'+CHR(13)+CHR(10)
	cTabela+= "	<thead>"+CHR(13)+CHR(10)
	cTabela+= "		<tr>"+CHR(13)+CHR(10)
	cTabela+= "			<th>Armaz&eacute;m</th>"+CHR(13)+CHR(10)
	cTabela+= "			<th>Descri&ccedil;&atilde;o</th>"+CHR(13)+CHR(10)
	cTabela+= "			<th>Saldo</th>"+CHR(13)+CHR(10)
	cTabela+= "		</tr>"+CHR(13)+CHR(10)
	cTabela+= "	</thead>"+CHR(13)+CHR(10)
	cTabela+= "	<tbody>"+CHR(13)+CHR(10)

	If QRS->(!Eof())
		While QRS->(!Eof())
			cTabela+= "	<tr>
			cTabela+= "		<td>"+QRS->ARMAZEM+"</td>"
			cTabela+= "		<td>"+FwNoAccent(Upper(Posicione("NNR",1,xFilial("NNR")+QRS->ARMAZEM,"NNR_DESCRI")))+"</td>"
			cTabela+= "		<td>"+cvaltochar(QRS->SALDO)+"</td>"
			cTabela+= "	</tr>"
			QRS->(dbSkip())
		End
		cTabela+="		</tbody>"+CHR(13)+CHR(10)
		cTabela+="</table>"+CHR(13)+CHR(10)

		QRS->(dbCloseArea())
	Else
		cTabela+= "	<tr>
		cTabela+= "		<td>**Sem saldo em estoque**</td>"
		cTabela+= "	</tr>"
	Endif

	cHtml:= cTabela

	Web Extended end

Return cHtml


/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ GetLimCred	¦ Autor ¦ Lucilene Mendes   ¦ Data ¦ 04.07.19 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Função utilizada no Ajax pra retornar o limite disponível  ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/
User Function GetLimCred()
	Local cHtml
	Local cCliente	:= Alltrim(HttpPost->cliente)
	Local nTotal	:= Val(HttpPost->valor)
	Local nSaldo	:= 0
	Local nToler	:= 0
	Local lVldLimite:= .F.

	Web Extended Init cHtml Start U_inSite()

	If Empty(HttpSession->CodVend)
		cHtml:= '<META HTTP-EQUIV="Refresh" CONTENT="0 ; URL=U_PortalLogin.apw">'
		Return cHtml
	endif

	lVldLimite:= GetNewPar("PR_VLDLIMT",.F.)
	If !lVldLimite
		cHtml:= cValtochar(99999999)+"|"+cValtochar(0)
	Else
		//Posiciona no cliente
		dbSelectArea("SA1")
		SA1->(dbSeek(xFilial("SA1")+cCliente))

		//Busca valor em pedidos liberados
		cQry:= "SELECT SUM(C6_VALOR) TOTAL FROM "+RetSqlName("SC6")+" SC6 "
		cQry+= "INNER JOIN "+RetSqlName("SC5")+" SC5 ON C5_FILIAL = C6_FILIAL AND C5_NUM  = C6_NUM AND C5_CLIENT = C6_CLI "
		cQry+= "AND C5_LOJACLI = C6_LOJA AND C5_LIBEROK = 'S' AND C5_NOTA = ' ' AND SC5.D_E_L_E_T_ = ' ' "
		cQry+= "WHERE C6_CLI = '"+SA1->A1_COD+"' AND C6_LOJA = '"+SA1->A1_LOJA+"' "
		cQry+= "AND NOT EXISTS (SELECT * FROM "+RetSqlName("SC9")+" SC9 WHERE C9_FILIAL = C5_FILIAL AND C9_PEDIDO = C5_NUM AND C9_BLCRED NOT IN (' ','10') "
		cQry+= "AND SC9.D_E_L_E_T_ = ' ') "
		cQry+= "AND SC6.D_E_L_E_T_ = ' ' "

		If Select("QRL") > 0
			QRL->(dbCloseArea())
		Endif
		APWExOpenQuery(cQry,'QRL',.T.)

		nSaldo:= SA1->A1_LC - (SA1->A1_SALDUP + QRL->TOTAL)
		nToler:= nSaldo * GetNewPar("PR_TOLERLC",0)/100 //Tolerancia de 1%
		//nSaldo:= nSaldo + nToler

		cHtml:= cValtochar(nSaldo)+"|"+cValtochar(nToler) //Alltrim(Transform(nSaldo,"@E 999,999,999,999.99"))
	Endif

	Web Extended end

Return cHtml

/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ DescVista	¦ Autor ¦ Lucilene Mendes   ¦ Data ¦ 21.08.19 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Verifica se a condição de pagamento tem desconto à vista   ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/
User Function DescVista()
	Local cHtml
	Local cCondicao	:= Alltrim(HttpPost->condicao)

	Web Extended Init cHtml Start U_inSite()
	cHtml:= cValtoChar(Posicione("SE4",1,xFilial("SE4")+cCondicao,"E4_DESCPED"))
	Web Extended end

Return cHtml

/*__________________________________________________________________________
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦Funçäo    ¦ InfGetAn    ¦ Autor ¦ Anderson Zelenski  ¦ Data ¦ 24.08.17 ¦¦¦
¦¦+----------+------------------------------------------------------------¦¦¦
¦¦¦Descriçäo ¦ Função para utilizar no Ajax pra retornar os anexos        ¦¦¦
¦¦+-----------------------------------------------------------------------+¦¦
¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦¦
¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
*/
/*
User Function InfGetAn()
Local cHtml
Local cCotacao	:= ""
Local cFornece	:= ""
Local cLoja		:= ""
Local cDirCot	:= "anexosPortal\cotacoes\"

Web Extended Init cHtml Start U_inSite()

	#IFDEF SMSDEBUG
	  conOut(Procname()+"("+ltrim(str(procline()))+") *** Portal ")
	  aInfo := HttpGet->aGets
	  For nI := 1 to len(aInfo)
	   conout('GET '+str(nI,3)+' = '+aInfo[nI]+' -> '+&("HTTPGET->"+aInfo[nI]))
	  Next
	  aInfo := HttpPost->aPost
	  For nI := 1 to len(aInfo)
	   conout('POST '+str(nI,3)+' = '+aInfo[nI]+' -> '+&("HTTPPOST->"+aInfo[nI]))
	  Next
	#ENDIF

	cCotacao	:= HttpPost->cotacao
	cFornece	:= HttpPost->fornece
	cLoja		:= HttpPost->loja

	//Verifica se existem anexos
    cDirCot += cCotacao+'\'+cFornece+cLoja+'\'
    cDirPortal := "../anexos/cotacoes/"+cCotacao+"/"+cFornece+cLoja+"/"

    aAnexos := DIRECTORY(cDirCot+"*.*","",,.T.)

	If Len(aAnexos) > 0
		cHTML := U_GetAnexos(aAnexos,cDirPortal)
	Else
		cHTML := "Sem Anexos para essa cotação."
	EndIf

Web Extended End

Return (cHTML)
Static Function NewDlg1()
/*
A tag abaixo define a criação e ativação do novo diálogo. Você pode colocar esta tag
onde quer que deseje em seu código fonte. A linha exata onde esta tag se encontra, definirá
quando o diálogo será exibido ao usuário.
Nota: Todos os objetos definidos no diálogo serão declarados como Local no escopo da
função onde a tag se encontra no código fonte.
*/

Return