#include "totvs.ch"
#include "topconn.ch"

/*/{Protheus.doc} MA415END
Disparado após o encerramento das operações da rotina de orçamentos MATA415 ( inclusão, alteração, exclusão )
Gravar as Tabelas de Auditoria do Orçamento.
Solicitante: Rodrigo
@type function
@author Aytel M. Fonseca.
@since 18/11/2020
@see https://tdn.totvs.com.br/display/public/PROT/MA415END
@history 22/08/2023, remover atalhos do teclado que so podem ser executados dentro das acoes de inclusao, alteracoes e exclusoes
/*/
User Function MA415END()
	Local aArea 	:= GetArea()
	Local cSQLExec 	:= ''	
	Local cOper		:= ""
	Local nX		:= 0

	// Na Função Copiar - Fonseca em 24.11.2020
	If ALTERA .AND. cCadastro == 'Orcamentos de Venda - COPIAR' 
		RecLock("SCJ",.F.)
			SCJ->CJ_VALIDA  := (dDataBase + 10)
			SCJ->CJ_DSCPERD := ' '
			SCJ->CJ_CODPERD := ' '
			SCJ->CJ_DTCANC  := CToD("")
			SCJ->CJ_USUARIO := Trim(cUserName)
			SCJ->CJ_CDCONCO := ' '
			SCJ->CJ_USRCANC := ' '
		MsUnlock("SCJ")
	EndIf

	If Inclui
		cOper := "1-INCLUSAO"
	// Copia
	ElseIf Altera .AND. cCadastro == 'Orcamentos de Venda - COPIAR' 
	 	cOper := "3-COPIA"
	ElseIf Altera 
	 	cOper := "2-ALTERACAO"
	EndIf

	If !Empty(AllTrim(cOper))
		cSQLExec := "INSERT INTO AUDIT_SCJ SELECT SYSDATE, '" + Upper(Trim(cUserName)) + "' ,'"+cOper+"', SCJ010.* FROM SCJ010 WHERE D_E_L_E_T_ = ' ' AND CJ_NUM = '" + Trim(CJ_NUM) + "' AND CJ_FILIAL = '" + xFilial("SCJ") + "'"
	    If TCSqlExec(cSQLExec) < 0
    	    Msgstop('Erro Alteração AUDIT_SCJ. MA415END' + Chr(13) + TCSQLError(),'Erro !!!')
	    Endif	

		cSQLExec := "INSERT INTO AUDIT_SCK SELECT SYSDATE, '" + Upper(Trim(cUserName)) + "' ,'"+cOper+"', SCK010.* FROM SCK010 WHERE D_E_L_E_T_ = ' ' AND CK_NUM = '" + Trim(CJ_NUM) + "' AND CK_FILIAL = '" + xFilial("SCK") + "'"
	    If TCSqlExec(cSQLExec) < 0
    	    Msgstop('Erro Alteração AUDIT_SCK. MA415END' + Chr(13) + TCSQLError(),'Erro !!!')
	    Endif	
	Endif

	// se a variavel existe
	If Type("a415Atalho") == "A"

		// remove atalhos usados na tela de inclusão/alteracao/exclusao
		For nX := 1 to Len(a415Atalho)
			SetKey(a415Atalho[nX][1] 	, Nil)
		Next

		// limpa os atalhos
		Public a415Atalho := {}
	Endif

	RestArea(aArea)
Return